Grammaire du langage de requête Google Ads

Vidéo : Validation des requêtes

Cette page contient la documentation de référence sur la grammaire du langage de requête Google Ads. Pour en savoir plus sur la structure des requêtes, consultez la section Structure des requêtes.

Voici la documentation de référence sur la grammaire du langage de requête Google Ads (dans la notation d'expression régulière) :

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

? indique un élément facultatif.
* signifie zéro ou plusieurs ; + signifie un ou plusieurs.
(xxxxxx) indique un regroupement.
[a-z0-9] signifie des plages de caractères.
| signifie "ou".

Règles et limites

  • L'opérateur REGEXP_MATCH utilise RE2 syntax.

  • Pour faire correspondre un caractère littéral [, ], % ou _ à l'aide de l'opérateur LIKE, placez le caractère entre crochets. Par exemple, la condition suivante correspond à toutes les valeurs campaign.name commençant par [Earth_to_Mars] :

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • L'opérateur LIKE ne peut être utilisé que sur un champ de chaîne, et non sur un tableau.

Précédent
Aperçu
Suivant
Structure d'une requête