Möchten Sie uns Feedback zur Google Ads API geben? Melde dich an, um an Nutzerstudien teilzunehmen.

Diese Seite wurde von der Cloud Translation API übersetzt.

Google Ads-Grammatik für Abfragesprache

Hier sehen Sie die Grammatikreferenz für die Google Ads Query Language (in regulärer Schreibweise):

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

?zeigt ein optionales Element an
* bedeutet null oder mehr; + steht für mindestens einen
(xxxxxx) steht für eine Gruppierung
[a-z0-9] steht für Zeichenbereiche
| steht für „oder“

Regeln und Einschränkungen

Der Operator REGEXP_MATCH verwendet RE2 Syntax.
Um ein literales [, ], % oder _ mit dem LIKE-Operator abzugleichen, das Zeichen in eckigen Klammern. Die folgende Bedingung stimmt beispielsweise mit alle campaign.name-Werte, die mit [Earth_to_Mars] beginnen:
```
campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'
```
Der Operator LIKE kann nur für ein Stringfeld verwendet werden, nicht für ein Array.