Grammatik der Google Ads-Abfragesprache

Diese Seite enthält die Grammatikreferenz der Google Ads-Abfragesprache. Details zur Abfragestruktur finden Sie unter Abfragestruktur.

Grammatikreferenz

Hier ist die Grammatikreferenz der Google Ads-Abfragesprache (in der Notation für reguläre Ausdrücke):

Query            -> SelectClause FromClause? WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName ("," FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering ("," Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*

Condition        -> FieldName IS NULL
                  | FieldName IS NOT NULL
                  | FieldName BETWEEN Value AND Value
                  | FieldName Operator Value
Operator         -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
                  | LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
                  | CONTAINS NONE | DURING
                  | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String
                  | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z]([a-zA-Z0-9._])*
ResourceName     -> [a-z]([a-zA-Z0-9_])*

StringList       -> "(" String ("," String)* ")"
LiteralList      -> "(" Literal ("," Literal)* ")"
NumberList       -> "(" Number ("," Number)* ")"

PositiveInteger  -> [1-9]([0-9])*
Number           -> -?[0-9]+(\.[0-9]+)?
String           -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar  -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar  -> [^"\\\r\n] | EscapeSequence
EscapeSequence   -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal          -> [a-zA-Z]([a-zA-Z0-9_])*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
                  | LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
                  | LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
                  | THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
  • ? gibt ein optionales Element an.
  • * bedeutet „null oder mehr“ und + bedeutet „eins oder mehr“.
  • (...) gibt eine Gruppierung an, während "(" und ")" für Literal klammern stehen.
  • [a-z0-9] steht für Zeichenbereiche und [^...] für alle Zeichen außer den aufgeführten Zeichen.
  • | steht für „oder“.

Regeln und Einschränkungen

  • FromClause ist erforderlich, wenn GoogleAdsService abgefragt wird, und muss weggelassen werden, wenn GoogleAdsFieldService abgefragt wird.

  • WhereClause unterstützt das Kombinieren von Bedingungen nur mit AND. Der logische Operator OR wird nicht unterstützt. Verwenden Sie stattdessen den Operator IN oder REGEXP_MATCH.

  • Der Operator REGEXP_MATCH verwendet die RE2-Syntax.

  • Wenn Sie mit dem Operator LIKE nach einem Literal [, ], % oder _ suchen möchten, setzen Sie das Zeichen in eckige Klammern. Die folgende Bedingung stimmt beispielsweise mit allen campaign.name-Werten überein, die mit [Earth_to_Mars] beginnen:

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • Der Operator LIKE kann nur für ein Stringfeld und nicht für ein Array verwendet werden.

Zurück
Übersicht
Weiter
Abfragestruktur