Google Ads 쿼리 언어 문법

이 페이지에는 Google Ads 쿼리 언어 문법 참조가 포함되어 있습니다. 쿼리 구조에 관한 자세한 내용은 쿼리 구조를 참고하세요.

문법 참조

다음은 Google Ads 쿼리 언어 문법 참조입니다 (정규 표현식 표기법 사용).

Query            -> SelectClause FromClause? WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName ("," FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering ("," Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*

Condition        -> FieldName IS NULL
                  | FieldName IS NOT NULL
                  | FieldName BETWEEN Value AND Value
                  | FieldName Operator Value
Operator         -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
                  | LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
                  | CONTAINS NONE | DURING
                  | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String
                  | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z]([a-zA-Z0-9._])*
ResourceName     -> [a-z]([a-zA-Z0-9_])*

StringList       -> "(" String ("," String)* ")"
LiteralList      -> "(" Literal ("," Literal)* ")"
NumberList       -> "(" Number ("," Number)* ")"

PositiveInteger  -> [1-9]([0-9])*
Number           -> -?[0-9]+(\.[0-9]+)?
String           -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar  -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar  -> [^"\\\r\n] | EscapeSequence
EscapeSequence   -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal          -> [a-zA-Z]([a-zA-Z0-9_])*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
                  | LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
                  | LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
                  | THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
  • ?는 선택적 요소를 나타냅니다.
  • *는 0개 이상을 의미하고 +는 1개 이상을 의미합니다.
  • (...)는 그룹화를 나타내고 "(" 및 ")"는 리터럴 괄호를 나타냅니다.
  • [a-z0-9] 는 문자 범위를 나타내고 [^...]는 나열된 문자를 제외한 모든 문자를 나타냅니다.
  • |는 '또는'을 나타냅니다.

규칙 및 제한사항

  • GoogleAdsService를 쿼리할 때는 FromClause가 필요하며 GoogleAdsFieldService를 쿼리할 때는 생략해야 합니다.

  • WhereClause는 AND로만 조건을 결합할 수 있습니다. 논리 OR은 지원되지 않습니다. 대신 IN 또는 REGEXP_MATCH 연산자를 사용하세요.

  • REGEXP_MATCH 연산자는 RE2 문법을 사용합니다.

  • LIKE 연산자를 사용하여 리터럴 [, ], % 또는 _와 일치시키려면 문자를 대괄호로 묶습니다. 예를 들어 다음 조건은 [Earth_to_Mars]로 시작하는 모든 campaign.name 값과 일치합니다.

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • LIKE 연산자는 배열이 아닌 문자열 필드에서만 사용할 수 있습니다.

이전
개요
다음
쿼리 구조