Google 広告クエリ言語の文法

このページでは、Google 広告クエリ言語の文法リファレンスについて説明します。クエリ構造の詳細については、クエリ構造をご覧ください。

文法リファレンス

Google 広告クエリ言語の文法リファレンス（正規表現表記）を以下に示します。

Query            -> SelectClause FromClause? WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName ("," FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering ("," Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*

Condition        -> FieldName IS NULL
                  | FieldName IS NOT NULL
                  | FieldName BETWEEN Value AND Value
                  | FieldName Operator Value
Operator         -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
                  | LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
                  | CONTAINS NONE | DURING
                  | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String
                  | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z]([a-zA-Z0-9._])*
ResourceName     -> [a-z]([a-zA-Z0-9_])*

StringList       -> "(" String ("," String)* ")"
LiteralList      -> "(" Literal ("," Literal)* ")"
NumberList       -> "(" Number ("," Number)* ")"

PositiveInteger  -> [1-9]([0-9])*
Number           -> -?[0-9]+(\.[0-9]+)?
String           -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar  -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar  -> [^"\\\r\n] | EscapeSequence
EscapeSequence   -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal          -> [a-zA-Z]([a-zA-Z0-9_])*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
                  | LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
                  | LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
                  | THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
  • ? は、省略可能な要素を示します。
  • * は 0 個以上、+ は 1 個以上を意味します。
  • (...) はグループ化を示し、"(" と ")" はリテラルの括弧を示します。
  • [a-z0-9] は文字範囲を示し、[^...] はリストにない任意の文字を示します。
  • | は「または」を表します。

ルールと制限

  • GoogleAdsService のクエリを実行する場合は FromClause が必要です。GoogleAdsFieldService のクエリを実行する場合は省略する必要があります。

  • WhereClause は、AND との条件の組み合わせのみをサポートします。論理 OR はサポートされていません。代わりに IN または REGEXP_MATCH 演算子を使用してください。

  • REGEXP_MATCH 演算子は RE2 構文を使用します。

  • LIKE 演算子を使用してリテラル [、]、%、_ を照合するには、文字を角かっこで囲みます。たとえば、次の条件は、[Earth_to_Mars] で始まるすべての campaign.name 値と一致します。

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • LIKE 演算子は、文字列フィールドでのみ使用できます。配列では使用できません。

前へ
概要
次へ
クエリの構造