Gramatyka języka zapytań Google Ads

Ta strona zawiera gramatykę języka zapytań Google Ads. Szczegółowe informacje o strukturze zapytania znajdziesz w sekcji Struktura zapytania.

Dokumentacja gramatyki

Oto gramatyka języka zapytań Google Ads (w notacji wyrażeń regularnych):

Query            -> SelectClause FromClause? WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName ("," FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering ("," Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*

Condition        -> FieldName IS NULL
                  | FieldName IS NOT NULL
                  | FieldName BETWEEN Value AND Value
                  | FieldName Operator Value
Operator         -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
                  | LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
                  | CONTAINS NONE | DURING
                  | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String
                  | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z]([a-zA-Z0-9._])*
ResourceName     -> [a-z]([a-zA-Z0-9_])*

StringList       -> "(" String ("," String)* ")"
LiteralList      -> "(" Literal ("," Literal)* ")"
NumberList       -> "(" Number ("," Number)* ")"

PositiveInteger  -> [1-9]([0-9])*
Number           -> -?[0-9]+(\.[0-9]+)?
String           -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar  -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar  -> [^"\\\r\n] | EscapeSequence
EscapeSequence   -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal          -> [a-zA-Z]([a-zA-Z0-9_])*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
                  | LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
                  | LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
                  | THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
  • ? oznacza element opcjonalny.
  • * oznacza zero lub więcej, a + oznacza co najmniej jeden.
  • Symbol (...) oznacza grupowanie, a symbole "(" i ")" oznaczają dosłowne nawiasy.
  • [a-z0-9] oznacza zakresy znaków, a [^...] – dowolny znak z wyjątkiem wymienionych znaków.
  • | oznacza „lub”.

Zasady i ograniczenia

  • Właściwość FromClause jest wymagana podczas wysyłania zapytań do usługi GoogleAdsService i musi zostać pominięta podczas wysyłania zapytań do usługi GoogleAdsFieldService.

  • WhereClause obsługuje łączenie warunków tylko z AND. Operator logiczny OR nie jest obsługiwany. Zamiast niego użyj operatora IN lub REGEXP_MATCH.

  • Operator REGEXP_MATCH używa składni RE2.

  • Aby dopasować literał [, ], % lub _ za pomocą operatora LIKE, umieść znak w nawiasach kwadratowych. Na przykład ten warunek pasuje do wszystkich wartości campaign.name, które zaczynają się od [Earth_to_Mars]:

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • Operatora LIKE można używać tylko w przypadku pola tekstowego, a nie tablicy.

Wstecz
Przegląd
Dalej
Struktura zapytania