這個頁面包含 Google Ads 查詢語言文法參考資料。如要瞭解查詢結構的詳細資料，請參閱「查詢結構」。
文法參考資料
以下是 Google Ads 查詢語言文法參考資料 (採用規則運算式標記)：
Query -> SelectClause FromClause? WhereClause? OrderByClause?
LimitClause? ParametersClause?
SelectClause -> SELECT FieldName ("," FieldName)*
FromClause -> FROM ResourceName
WhereClause -> WHERE Condition (AND Condition)*
OrderByClause -> ORDER BY Ordering ("," Ordering)*
LimitClause -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*
Condition -> FieldName IS NULL
| FieldName IS NOT NULL
| FieldName BETWEEN Value AND Value
| FieldName Operator Value
Operator -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
| LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
| CONTAINS NONE | DURING
| REGEXP_MATCH | NOT REGEXP_MATCH
Value -> Literal | LiteralList | Number | NumberList | String
| StringList | Function
Ordering -> FieldName (ASC | DESC)?
FieldName -> [a-z]([a-zA-Z0-9._])*
ResourceName -> [a-z]([a-zA-Z0-9_])*
StringList -> "(" String ("," String)* ")"
LiteralList -> "(" Literal ("," Literal)* ")"
NumberList -> "(" Number ("," Number)* ")"
PositiveInteger -> [1-9]([0-9])*
Number -> -?[0-9]+(\.[0-9]+)?
String -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar -> [^"\\\r\n] | EscapeSequence
EscapeSequence -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal -> [a-zA-Z]([a-zA-Z0-9_])*
Function -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
| LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
| LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
| THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
?表示選用元素。*表示零或多個；+表示一或多個。(...)表示分組，"("和")"則表示字面上的括號。[a-z0-9]代表字元範圍，[^...]代表列出字元以外的任何字元。|代表「或」。
規則和限制
查詢
GoogleAdsService時必須提供FromClause，查詢GoogleAdsFieldService時則必須省略。WhereClause僅支援與AND合併條件。系統不支援邏輯OR，請改用IN或REGEXP_MATCH運算子。REGEXP_MATCH運算子使用 RE2 語法。如要使用
LIKE運算子比對[、]、%或_字元，請用方括號括住該字元。舉例來說，下列條件會比對出所有以[Earth_to_Mars]開頭的campaign.name值：campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'LIKE運算子只能用於字串欄位，不能用於陣列。