ไวยากรณ์ภาษาในการค้นหาของ Google Ads

วิดีโอ: การตรวจสอบการค้นหา

การอ้างอิงไวยากรณ์เกี่ยวกับภาษาของคำค้นหาของ Google Ads (ในรูปแบบนิพจน์ทั่วไป) มีดังนี้

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

?หมายถึงองค์ประกอบที่ไม่บังคับ
* หมายถึง 0 ขึ้นไป + หมายถึง
(xxxxxx) หมายถึงการจัดกลุ่ม
[a-z0-9] หมายถึงช่วงอักขระ
| ย่อมาจาก "หรือ"

กฎและข้อจำกัด

  • โอเปอเรเตอร์ REGEXP_MATCH ใช้ RE2 ไวยากรณ์

  • หากต้องการจับคู่ [, ], % หรือ _ ตามตัวอักษรโดยใช้โอเปอเรเตอร์ LIKE ให้เซอร์ราวด์ อักขระในวงเล็บเหลี่ยม ตัวอย่างเช่น เงื่อนไขต่อไปนี้ตรงกับ ค่า campaign.name ทั้งหมดที่ขึ้นต้นด้วย [Earth_to_Mars]:

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • โอเปอเรเตอร์ LIKE ใช้ได้กับช่องสตริงเท่านั้น และจะใช้ในอาร์เรย์ไม่ได้

ก่อนหน้า
ภาพรวม
ถัดไป
โครงสร้างการค้นหา