Google Ads क्वेरी भाषा व्याकरण

अभी तक किसी भी व्यक्ति ने चेक इन नहीं किया है वीडियो: क्वेरी की पुष्टि करना

यहां Google Ads क्वेरी लैंग्वेज का व्याकरण संदर्भ दिया गया है (रेगुलर एक्सप्रेशन नोटेशन में):

Query            -> SelectClause FromClause WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName (, FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering (, Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal = Value (, Literal = Value)*

Condition        -> FieldName Operator Value
Operator         -> = | != | > | >= | < | <= | IN | NOT IN |
                    LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL |
                    CONTAINS NONE | IS NULL | IS NOT NULL | DURING |
                    BETWEEN | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String |
                    StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z] ([a-zA-Z0-9._])*
ResourceName     -> [a-z] ([a-zA-Z_])*

StringList       -> ( String (, String)* )
LiteralList      -> ( Literal (, Literal)* )
NumberList       -> ( Number (, Number)* )

PositiveInteger  -> [1-9] ([0-9])*
Number           -> -? [0-9]+ (. [0-9] [0-9]*)?
String           -> (' Char* ') | (" Char* ")
Literal          -> [a-zA-Z0-9_]*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS |
                    LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN |
                    LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY |
                    THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY

?एक वैकल्पिक एलिमेंट का संकेत देता है
* का मतलब है, शून्य या उससे ज़्यादा; + का मतलब है एक या ज़्यादा
(xxxxxx) एक ग्रुप के बारे में बताता है
[a-z0-9], वर्ण सीमाओं को दर्शाता है
| का मतलब है "या"

नियम और सीमाएं

  • REGEXP_MATCH ऑपरेटर, RE2 का इस्तेमाल करता है सिंटैक्स का इस्तेमाल करते हैं.

  • LIKE ऑपरेटर का इस्तेमाल करके, सराउंड साउंड [, ], % या _ को लिटरल वैल्यू से मैच करने के लिए, सराउंड साउंड स्क्वेयर ब्रैकेट में रखें. उदाहरण के लिए, नीचे दी गई शर्त मेल खाती है [Earth_to_Mars] से शुरू होने वाली सभी campaign.name वैल्यू:

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • LIKE ऑपरेटर का इस्तेमाल सिर्फ़ स्ट्रिंग फ़ील्ड पर किया जा सकता है, किसी अरे पर नहीं.

पीछे जाएं
खास जानकारी
आगे बढ़ें
क्वेरी स्ट्रक्चर