Alan maskeleri

Google Ads API'de güncellemeler bir alan maskesi kullanılarak yapılır. Alan maskesi, güncellemeyle değiştirmek istediğiniz tüm alanları listeler ve alan maskesinde olmayan belirtilen alanlar, sunucuya gönderilse bile yoksayılır.

FieldMasks yardımcı programı

Alan maskeleri oluşturmak için önerilen yöntem, yerleşik alan maskesi yardımcı programımızı (FieldMasks) kullanmaktır. Bu yardımcı program, alan maskelerini sıfırdan oluşturmak yerine değiştirilmiş bir nesneden oluşturmanıza olanak tanır.

Bir kampanyayı güncellemeye ilişkin örnek:

use Google::Ads::GoogleAds::Utils::FieldMasks qw(all_set_fields_of field_mask);

my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => "PAUSED",
    networkSettings =>
      Google::Ads::GoogleAds::V26::Resources::NetworkSettings
      ->new({
        targetSearchNetwork => "false",
      }),
  });

my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

Bu örnekte, API'nin hangi kampanyanın güncellendiğini bilmesi için öncelikle ResourceNames yardımcı programını kullanarak kaynak adını ayarlayarak bir Campaign nesnesi oluşturulur.

Örnekte, kampanyada FieldMasks::all_set_fields_of() yöntemi kullanılarak tüm ayarlanmış alanları listeleyen bir alan maskesi otomatik olarak oluşturulur. Ardından, döndürülen maskeyi doğrudan güncelleme çağrısına iletebilirsiniz.

FieldMasks::all_set_fields_of(), FieldMasks::field_mask() için kolaylık sağlayan bir yöntemdir. İlettiğiniz nesneyi aynı sınıftan boş bir nesneyle karşılaştırır. Yukarıdaki kodda şunları da kullanabilirsiniz:

field_mask(
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({}),
  $campaign
)

all_set_fields_of($campaign) yerine.

Manuel olarak maske oluşturma

Sıfırdan bir alan maskesi oluşturmak için önce bir Google::Ads::GoogleAds::Common::FieldMask nesnesi oluşturun, ardından değiştirmek istediğiniz tüm alanların adlarıyla doldurulmuş bir dizi referansı oluşturun ve son olarak dizi referansını alan maskesinin paths alanına atayın:

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
  paths => ["status", "name"],
});

Nesne alanlarını ve alt alanlarını güncelleme

Nesne alanlarının alt alanları olabilir (ör. target_cpa_micros gibi alt alanları içeren MaximizeConversions) veya hiç alt alanı olmayabilir (ör. ManualCpm).

Tanımlanmış alt alanları olmayan nesne alanları

Perl'deki bir nesne alanı, gRPC üzerinde çalışan istemci kitaplıklarındaki bir protobuf MESSAGE ile eşdeğerdir. Herhangi bir alt alanla tanımlanmamış bir nesne alanını güncellerken önceki bölümde açıklandığı gibi alan maskesi oluşturmak için FieldMasks yardımcı programını kullanın.

Tanımlanmış alt alanları olan nesne alanları

Alt alanlarla tanımlanan bir nesne alanını, bu mesajdaki alt alanlardan herhangi birini açıkça ayarlamadan güncellerken, değiştirilebilir nesne alt alanlarının her birini FieldMask alanına manuel olarak eklemeniz gerekir. Bu, sıfırdan alan maskesi oluşturan önceki örneğe benzer.

Sık karşılaşılan bir örnek, yeni teklif stratejisindeki alanlardan hiçbirini ayarlamadan bir kampanyanın teklif stratejisini güncellemektir. Aşağıdaki örnekte, teklif stratejisindeki alt alanlardan herhangi biri ayarlanmadan MaximizeConversions teklif stratejisini kullanmak için bir kampanyanın nasıl güncelleneceği gösterilmektedir.

Bu durumda, FieldMasks yardımcı programının all_set_fields_of() ve field_mask() yöntemlerini kullanmak istenen amaca ulaşmaz.

Aşağıdaki örnekte, maximize_conversions içeren bir alan maskesi oluşturulmaktadır. Ancak Google Ads API, alanların yanlışlıkla temizlenmesini önlemek için bu davranışa izin vermez ve FieldMaskError.FIELD_HAS_SUBFIELDS hatası verir.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V26::Resources::MaximizeConversions
      ->new(),
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask includes 'maximize_conversions',
# which produces a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

# Sends the operation in a mutate request that results in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
  customerId => $customer_id,
  operations => [$campaign_operation],
});

Aşağıdaki örnekte, bir kampanyanın alt alanlarından herhangi birini ayarlamadan MaximizeConversions teklif stratejisini kullanacak şekilde nasıl doğru şekilde güncelleneceği gösterilmektedir.

# Creates a campaign with the proper resource name.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
  });

# Creates a field mask from the existing campaign and adds the mutable subfield
# on the MaximizeConversions bidding strategy to the field mask. Because this
# field is included in the field mask but excluded from the campaign object,
# the Google Ads API sets the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# See the guide on assigning standard and portfolio bidding strategies
# (/google-ads/api/docs/campaigns/bidding/assign-strategies).
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => $field_mask,
  });

Alanları temizle

Alanlar, önceki örnekte gösterildiği gibi alan maskesine eklenerek veya boş ya da tanımlanmamış bir değere ayarlanarak açıkça temizlenebilir. Örneğin, MaximizeConversions teklif stratejisini kullanan bir kampanyanız olduğunu ve target_cpa_micros alanının 0 değerinden büyük bir değere ayarlandığını varsayalım.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V26::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V26::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V26::Resources::MaximizeConversions
      ->new({
        targetCpaMicros => 0,
      }),
  });

# Constructs an operation using all_set_fields_of to derive the update mask,
# which includes 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V26::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

İç içe yerleştirilmiş alt alanları olan alanların yalnızca her bir alt alanın ayrı ayrı temizlenmesiyle temizlenebileceğini unutmayın. Bu durum, Tanımlanmış alt alanları olan nesne alanları bölümünde gösterilmiştir.