Alan maskeleri

Google Ads API'de güncellemeler alan maskesi kullanılarak yapılır. Alan maskesi, güncelleme ile değiştirmeyi planladığınız tüm alanları listeler ve alan maskesinde olmayan belirtilen alanlar, sunucuya gönderilse bile yoksayılır.

FieldMasks yardımcı programı

Alan maskeleri oluşturmak için önerilen yöntem, sıfırdan oluşturmak yerine değiştirilmiş bir nesneden alan maskeleri oluşturmanıza olanak tanıyan yerleşik alan maskesi yardımcı programımızı (FieldMasks) kullanmaktır.

Kampanya güncelleme örneğini aşağıda bulabilirsiniz:

use Google::Ads::GoogleAds::Utils::FieldMasks qw(all_set_fields_of field_mask);

my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => "PAUSED",
    networkSettings =>
      Google::Ads::GoogleAds::V25::Resources::NetworkSettings
      ->new({
        targetSearchNetwork => "false",
      }),
  });

my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

Bu örnekte, API'nin hangi kampanyanın güncellendiğini bilmesi için önce ResourceNames yardımcı programı kullanılarak kaynak adı ayarlanarak bir Campaign nesnesi oluşturulur.

Örnekte, tüm ayarlanmış alanları numaralandıran bir alan maskesini otomatik olarak oluşturmak için kampanyada FieldMasks::all_set_fields_of() yöntemi kullanılmaktadır. Daha sonra döndürülen maskeyi doğrudan güncelleme çağrısına iletebilirsiniz.

FieldMasks::all_set_fields_of(), FieldMasks::field_mask() için kolaylık sağlayan bir yöntemdir. Bu işlev, iletilen nesnenizi aynı sınıftaki boş bir nesneyle karşılaştırır. Yukarıdaki kodda şunları da kullanabilirsiniz:

field_mask(
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({}),
  $campaign
)

yerine all_set_fields_of($campaign) kullanın.

Manuel olarak maske oluşturma

Sıfırdan bir alan maskesi oluşturmak için önce bir Google::Ads::GoogleAds::Common::FieldMask nesnesi oluşturur, ardından değiştirmeyi planladığınız tüm alanların adlarıyla doldurulmuş bir dizi referansı oluşturur ve son olarak dizi referansını alan maskesinin paths alanına atarsınız:

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
  paths => ["status", "name"],
});

Nesne alanlarını ve alt alanlarını güncelleme

Nesne alanları, alt alanlara (ör. MaximizeConversions, target_cpa_micros gibi alt alanları içerir) sahip olabilir veya hiç alt alanı olmayabilir (ör. ManualCpm).

Tanımlanmış alt alanları olmayan nesne alanları

Perl'deki bir nesne alanı, gRPC üzerinde çalışan istemci kitaplıklarında bir protobuf MESSAGE ile eşdeğerdir. Alt alanlarla tanımlanmamış bir nesne alanını güncellerken, önceki bölümde açıklandığı gibi alan maskesi oluşturmak için FieldMasks yardımcı programını kullanın.

Tanımlanmış alt alanlara sahip nesne alanları

Bir mesajdaki alt alanların hiçbirini açıkça ayarlamadan alt alanlarla tanımlanmış bir nesne alanını güncellerken, her bir değiştirilebilir nesne alt alanını FieldMask'ye manuel olarak eklemeniz gerekir. Bu işlem, alan maskesini sıfırdan oluşturan önceki örneğe benzer.

Bunun yaygın bir örneği, yeni teklif stratejisindeki alanlardan herhangi birini ayarlamadan bir kampanyanın teklif stratejisini güncellemedir. Aşağıdaki örnekte, teklif stratejisinde herhangi bir alt alan belirlemeden bir kampanyayı MaximizeConversions teklif stratejisini kullanacak şekilde nasıl güncelleyeceğiniz gösterilmektedir.

Bu durumda, FieldMasks yardımcı programının all_set_fields_of() ve field_mask() yöntemlerinin kullanılması amaçlanan hedefi gerçekleştirmez.

Aşağıdaki örnek, maximize_conversions içeren bir alan maskesi oluşturur. Ancak Google Ads API, alanların yanlışlıkla temizlenmesini önlemek için bu davranışa izin vermez ve FieldMaskError.FIELD_HAS_SUBFIELDS hatası oluşturur.

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V25::Resources::MaximizeConversions
      ->new(),
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask includes 'maximize_conversions',
# which produces a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

# Sends the operation in a mutate request that results in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
  customerId => $customer_id,
  operations => [$campaign_operation],
});

Aşağıdaki örnekte, alt alanlarından herhangi birini ayarlamadan MaximizeConversions teklif stratejisini kullanmak için bir kampanyanın nasıl doğru şekilde güncelleneceği gösterilmektedir.

# Creates a campaign with the proper resource name.
my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
  });

# Creates a field mask from the existing campaign and adds the mutable subfield
# on the MaximizeConversions bidding strategy to the field mask. Because this
# field is included in the field mask but excluded from the campaign object,
# the Google Ads API sets the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# See the guide on assigning standard and portfolio bidding strategies
# (/google-ads/api/docs/campaigns/bidding/assign-strategies).
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => $field_mask,
  });

Alanları temizle

Alanlar, önceki örnekte gösterildiği gibi alan maskesine eklenerek veya alan boş ya da tanımlanmamış bir değere ayarlanarak açıkça temizlenebilir. Örneğin, MaximizeConversions teklif stratejisinin kullanıldığı bir kampanyanız olduğunu ve target_cpa_micros alanının 0 değerinden büyük bir değerle ayarlandığını varsayalım.

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V25::Resources::MaximizeConversions
      ->new({
        targetCpaMicros => 0,
      }),
  });

# Constructs an operation using all_set_fields_of to derive the update mask,
# which includes 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

İç içe yerleştirilmiş alt alanlara sahip alanların yalnızca her bir alt alan temizlenerek temizlenebileceğini unutmayın. Bu durum, Tanımlanmış alt alanlara sahip nesne alanları bölümünde gösterilmiştir.