Google は AI 技術を使用して、コンテンツをご希望の言語に翻訳しています。AI 翻訳には誤りが含まれる場合があります。

フィールドマスク

Google Ads API では、フィールドマスクを使用して更新が行われます。フィールドマスクには、更新で変更するすべてのフィールドがリストされます。フィールドマスクに含まれていない指定されたフィールドは、サーバーに送信されても無視されます。

FieldMasks ユーティリティ

フィールドマスクを生成するおすすめの方法は、組み込みのフィールドマスクユーティリティ（FieldMasks）を使用することです。これにより、フィールドマスクをゼロから構築するのではなく、変更されたオブジェクトから生成できます。

キャンペーンを更新する例を次に示します。

use Google::Ads::GoogleAds::Utils::FieldMasks qw(all_set_fields_of field_mask);

my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    status => "PAUSED",
    networkSettings =>
      Google::Ads::GoogleAds::V25::Resources::NetworkSettings
      ->new({
        targetSearchNetwork => "false",
      }),
  });

my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

この例では、まず ResourceNames ユーティリティを使用してリソース名を設定し、Campaign オブジェクトを作成します。これにより、API はどのキャンペーンが更新されているかを認識します。

この例では、キャンペーンの FieldMasks::all_set_fields_of() メソッドを使用して、設定されたすべてのフィールドを列挙するフィールドマスクを自動的に生成します。返されたマスクは、更新呼び出しに直接渡すことができます。

FieldMasks::all_set_fields_of() は FieldMasks::field_mask() のコンビニエンスメソッドです。渡されたオブジェクトを同じクラスの空のオブジェクトと比較します。上記のコードでは、次のものも使用できます。

field_mask(
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({}),
  $campaign
)

ではなく、all_set_fields_of($campaign) を使用します。

マスクを手動で作成する

フィールドマスクをゼロから作成するには、まず Google::Ads::GoogleAds::Common::FieldMask オブジェクトを作成し、変更するすべてのフィールドの名前が入力された配列参照を作成して、最後に配列参照をフィールドマスクの paths フィールドに割り当てます。

my $field_mask = Google::Ads::GoogleAds::Common::FieldMask->new({
  paths => ["status", "name"],
});

オブジェクトフィールドとそのサブフィールドを更新する

オブジェクトフィールドにはサブフィールド（target_cpa_micros などのサブフィールドを含む MaximizeConversions など）を含めることも、サブフィールドをまったく含めない（ManualCpm など）こともできます。

サブフィールドが定義されていないオブジェクトフィールド

Perl のオブジェクトフィールドは、gRPC で実行されているクライアントライブラリの protobuf MESSAGE に相当します。サブフィールドで定義されていないオブジェクトフィールドを更新する場合は、前のセクションで説明したように、FieldMasks ユーティリティを使用してフィールドマスクを生成します。

サブフィールドが定義されたオブジェクトフィールド

サブフィールドで定義されたオブジェクトフィールドを更新するときに、そのメッセージのサブフィールドを明示的に設定しない場合は、以前の例のように、変更可能なオブジェクトサブフィールドをそれぞれ FieldMask に手動で追加する必要があります。

一般的な例としては、新しい入札戦略のフィールドを何も設定せずに、キャンペーンの入札戦略を更新することがあります。次の例は、入札戦略のサブフィールドを設定せずに MaximizeConversions 入札戦略を使用するようにキャンペーンを更新する方法を示しています。

この場合、FieldMasks ユーティリティの all_set_fields_of() メソッドと field_mask() メソッドを使用しても、目的の目標を達成できません。

次の例では、maximize_conversions を含むフィールドマスクを生成します。ただし、Google Ads API では、フィールドの誤ったクリアを防ぐためにこの動作が許可されず、FieldMaskError.FIELD_HAS_SUBFIELDS エラーが生成されます。

# Creates a campaign with the proper resource name and an empty
# MaximizeConversions field.
my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V25::Resources::MaximizeConversions
      ->new(),
  });

# Constructs an operation, using the FieldMasks' all_set_fields_of utility to
# derive the update mask. The field mask includes 'maximize_conversions',
# which produces a FieldMaskError.FIELD_HAS_SUBFIELDS error.
my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

# Sends the operation in a mutate request that results in a
# FieldMaskError.FIELD_HAS_SUBFIELDS error because empty object fields cannot
# be included in a field mask.
my $response = $api_client->CampaignService()->mutate({
  customerId => $customer_id,
  operations => [$campaign_operation],
});

次の例は、サブフィールドを設定せずに MaximizeConversions 入札戦略を使用するようにキャンペーンを適切に更新する方法を示しています。

# Creates a campaign with the proper resource name.
my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
  });

# Creates a field mask from the existing campaign and adds the mutable subfield
# on the MaximizeConversions bidding strategy to the field mask. Because this
# field is included in the field mask but excluded from the campaign object,
# the Google Ads API sets the campaign's bidding strategy to a
# MaximizeConversions object with none of its subfields set.
# Only include 'maximize_conversions.target_cpa_micros' in the field mask
# as it is the only mutable subfield on MaximizeConversions when used as a
# standard bidding strategy.
#
# See the guide on assigning standard and portfolio bidding strategies
# (/google-ads/api/docs/campaigns/bidding/assign-strategies).
my $field_mask = all_set_fields_of($campaign);
push @{$field_mask->{paths}}, "maximize_conversions.target_cpa_micros";

# Creates an operation to update the campaign with the specified fields.
my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => $field_mask,
  });

フィールドをクリア

フィールドは、前の例に示すようにフィールドマスクに追加するか、フィールドを空の値または未定義の値に設定することで、明示的にクリアできます。たとえば、MaximizeConversions 入札戦略を使用するキャンペーンがあり、target_cpa_micros フィールドに 0 より大きい値が設定されているとします。

# Creates a campaign with the proper resource name and a MaximizeConversions
# object with target_cpa_micros set to 0.
my $campaign =
  Google::Ads::GoogleAds::V25::Resources::Campaign->new({
    resourceName =>
      Google::Ads::GoogleAds::V25::Utils::ResourceNames::campaign(
        $customer_id, $campaign_id
      ),
    maximizeConversions =>
      Google::Ads::GoogleAds::V25::Resources::MaximizeConversions
      ->new({
        targetCpaMicros => 0,
      }),
  });

# Constructs an operation using all_set_fields_of to derive the update mask,
# which includes 'maximize_conversions.target_cpa_micros'.
my $campaign_operation =
  Google::Ads::GoogleAds::V25::Services::CampaignService::CampaignOperation
  ->new({
    update     => $campaign,
    updateMask => all_set_fields_of($campaign),
  });

ネストされたサブフィールドを含むフィールドは、サブフィールドが定義されたオブジェクトフィールドで説明されているように、個々のサブフィールドをクリアすることでのみクリアできます。

フィールド マスク コレクションでコンテンツを整理 必要に応じて、コンテンツの保存と分類を行います。