IMA SDK आपकी वेबसाइटों और ऐप्लिकेशन में मल्टीमीडिया विज्ञापनों को इंटिग्रेट करना आसान बनाते हैं. IMA SDK, किसी भी VAST का पालन करने वाले विज्ञापन सर्वर से विज्ञापनों का अनुरोध कर सकते हैं. साथ ही, आपके ऐप्लिकेशन में विज्ञापन चलाने की सुविधा को मैनेज कर सकते हैं. IMA डीएआई SDK टूल की मदद से, ऐप्लिकेशन विज्ञापन और कॉन्टेंट के लिए स्ट्रीम का अनुरोध करते हैं, फिर चाहे वह वीओडी (वीडियो ऑन डिमांड) हो या लाइव. इसके बाद, SDK टूल एक साथ कई वीडियो स्ट्रीम दिखाता है, ताकि आपको अपने ऐप्लिकेशन में विज्ञापन और कॉन्टेंट वीडियो के बीच स्विच करने का काम मैनेज न करना पड़े.
अपनी पसंद का डीएआई सलूशन चुनें
पूरी सेवा वाला डीएआई
इस गाइड में IMA डीएआई SDK टूल को सामान्य वीडियो प्लेयर ऐप्लिकेशन में इंटिग्रेट करने का तरीका बताया गया है. अगर आपको पूरे किए गए सैंपल इंटिग्रेशन को देखना या उसे फ़ॉलो करना है, तो GitHub से बेसिक उदाहरण डाउनलोड करें.
IMA डीएआई की खास जानकारी
IMA डीएआई को लागू करने के तरीके में, SDK टूल के दो मुख्य कॉम्पोनेंट शामिल हैं. इनके बारे में इस गाइड में बताया गया है:
StreamRequest
: एक ऑब्जेक्ट जो स्ट्रीम के अनुरोध के बारे में बताता है. स्ट्रीम के अनुरोध, मांग पर वीडियो या लाइव स्ट्रीम के लिए हो सकते हैं. अनुरोधों में एक Content ID, एपीआई पासकोड या पुष्टि करने वाले टोकन, और अन्य पैरामीटर के बारे में बताया जाता है.StreamManager
: एक ऑब्जेक्ट जो डाइनैमिक विज्ञापन इंसर्शन की स्ट्रीम और डीएआई बैकएंड के साथ इंटरैक्शन को मैनेज करता है. स्ट्रीम मैनेजर, ट्रैकिंग पिंग मैनेज करता है और स्ट्रीम और विज्ञापन इवेंट को पब्लिशर को भेजता है.
ज़रूरी शर्तें
- हमारे साथ काम करने के तरीके की जानकारी देने वाले पेज को पढ़ें और पक्का करें कि आपको जिस उदाहरण का इस्तेमाल करना है वह Google Pay के साथ काम करता है या नहीं.
- हमारा Roku सैंपल प्लेयर कोड डाउनलोड करें
- यह पुष्टि करने के लिए कि आपका डेवलपमेंट सेट अप काम कर रहा है, सैंपल प्लेयर कोड को Roku डिवाइस पर डिप्लॉय करें.
अपना वीडियो चलाएं
सैंपल वीडियो प्लेयर, कॉन्टेंट वीडियो को अलग-अलग तरह से चलाता है. अपने Roku प्लेयर में सैंपल प्लेयर को डिप्लॉय करें. इससे यह पक्का किया जा सकेगा कि आपका डेवलपमेंट एनवायरमेंट सही तरीके से सेट अप किया गया हो.
अपने वीडियो प्लेयर को IMA डीएआई स्ट्रीम प्लेयर में बदलें
स्ट्रीम प्लेयर लागू करने के लिए, यह तरीका अपनाएं.
Sdk.xml बनाएं
अपने प्रोजेक्ट में MainScene.xml
के साथ Sdk.xml
नाम की एक नई फ़ाइल जोड़ें और यह बॉयलरप्लेट जोड़ें:
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
' Your code goes here.
]]>
</script>
</component>
इस गाइड में आपको इन दोनों फ़ाइलों में बदलाव करना होगा.
Roku विज्ञापन फ़्रेमवर्क लोड करें
IMA डीएआई SDK टूल, Roku विज्ञापन फ़्रेमवर्क पर निर्भर करता है. फ़्रेमवर्क लोड करने के लिए, manifest
और Sdk.xml
में यह जानकारी जोड़ें:
मेनिफ़ेस्ट
bs_libs_required=roku_ads_lib,googleima3
Sdk.xml
Library "Roku_Ads.brs"
Library "IMA3.brs"
IMA डीएआई SDK टूल लोड करें
IMA डाइनैमिक ऐड इंसर्शन स्ट्रीम को लोड करने के लिए, सबसे पहले IMA डीएआई SDK टूल को लोड करना शुरू करें. नीचे दी गई जानकारी, IMA डीएआई SDK टूल की स्क्रिप्ट को लोड करती है.
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
</interface>
...
Sub init()
m.top.functionName = "runThread"
End Sub
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
End Sub
Sub loadSdk()
If m.sdk = invalid
m.sdk = New_IMASDK()
End If
m.top.sdkLoaded = true
End Sub
अब MainScene.xml
में यह टास्क शुरू करें और कॉन्टेंट स्ट्रीम लोड करने के लिए, इस टास्क को हटाएं.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
m.sdkTask.control = "RUN"
end function
Sub onSdkLoaded(message as Object)
print "----- onSdkLoaded --- control ";message
End Sub
Sub onSdkLoadedError(message as Object)
print "----- errors in the sdk loading process --- ";message
End Sub
IMA स्ट्रीम प्लेयर बनाएं
इसके बाद, आपको IMA स्ट्रीम प्लेयर बनाने के लिए, अपने मौजूदा roVideoScreen
का इस्तेमाल करना होगा. यह स्ट्रीम प्लेयर तीन कॉलबैक तरीके लागू करता है: loadUrl
,
adBreakStarted
, और adBreakEnded
. साथ ही, स्ट्रीम लोड हो जाने पर ट्रिक प्ले को बंद कर दें. इससे उपयोगकर्ता, विज्ञापन के लिए ब्रेक शुरू होने वाले इवेंट के चालू होने से पहले ही, वीडियो शुरू होने से पहले दिखने वाले किसी विज्ञापन को स्किप नहीं कर सकते.
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
</interface>
...
Sub setupVideoPlayer()
sdk = m.sdk
m.player = sdk.createPlayer()
m.player.top = m.top
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function
m.player.adBreakEnded = Function(adBreakInfo as Object)
print "---- Ad Break Ended ---- "
m.top.adPlaying = False
m.top.video.enableTrickPlay = true
End Function
End Sub
स्ट्रीम का अनुरोध करना और उसे लागू करना
अब आपके पास स्ट्रीम प्लेयर है, तो स्ट्रीम का अनुरोध किया जा सकता है और उसे पूरा किया जा सकता है.
इस उदाहरण में, लाइव स्ट्रीम और वीओडी (वीडियो ऑन डिमांड) स्ट्रीम का डेटा है. इसमें वीओडी (वीडियो ऑन डिमांड) स्ट्रीम का इस्तेमाल किया जाता है. हालांकि, selectedStream
को m.testVodStream
से m.testLiveStream
में बदलकर, लाइव स्ट्रीम का इस्तेमाल किया जा सकता है.
AdUI जैसे, adChoices आइकॉन के साथ काम करने के लिए, आपको उस नोड का रेफ़रंस भी देना होगा जिसमें आपका कॉन्टेंट वीडियो है.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testLiveStream = {
title: "Livestream",
assetKey: "sN_IYUG8STe1ZzhIIE_ksA",
apiKey: "",
type: "live"
}
m.testVodStream = {
title: "VOD stream"
contentSourceId: "2548831",
videoId: "tears-of-steel",
apiKey: "",
type: "vod"
}
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
<field id="streamData" type="assocarray" />
<field id="streamManagerReady" type="Boolean" />
</interface>
...
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
End Sub
Sub loadStream()
sdk = m.sdk
sdk.initSdk()
setupVideoPlayer()
request = {}
streamData = m.top.streamData
if streamData.type = "live"
request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey)
else if streamData.type = "vod"
request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey)
else
request = sdk.CreateStreamRequest()
end if
request.player = m.player
request.videoObject = m.top.video
' Required to support UI elements for 'Why This Ad?' and skippability
request.adUiNode = m.top.video
requestResult = sdk.requestStream(request)
If requestResult <> Invalid
print "Error requesting stream ";requestResult
Else
m.streamManager = Invalid
While m.streamManager = Invalid
sleep(50)
m.streamManager = sdk.getStreamManager()
End While
If m.streamManager = Invalid or m.streamManager["type"] <> Invalid or m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "error ";m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
Else
m.top.streamManagerReady = True
addCallbacks()
m.streamManager.start()
End If
End If
End Sub
इवेंट लिसनर जोड़ें और स्ट्रीम शुरू करें
स्ट्रीम का अनुरोध करने के बाद, बस कुछ ही काम बचे हैं: विज्ञापन की प्रोग्रेस ट्रैक करने, स्ट्रीम को शुरू करने, और Roku मैसेज को SDK टूल पर फ़ॉरवर्ड करने के लिए, इवेंट सुनने वालों को जोड़ना.
MainScene.xml
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.observeField("urlData", "urlLoadRequested")
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sub urlLoadRequested(message as Object)
print "Url Load Requested ";message
data = message.getData()
playStream(data.manifest)
End Sub
Sub playStream(url as Object)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.url = url
vidContent.title = m.videoTitle
vidContent.streamformat = "hls"
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
End Sub
Sdk.xml
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
If m.top.streamManagerReady
runLoop()
End If
End Sub
Sub runLoop()
m.top.video.timedMetaDataSelectionKeys = ["*"]
m.port = CreateObject("roMessagePort")
' Listen to all fields.
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
fields = m.top.video.getFields()
for each field in fields
m.top.video.observeField(field, m.port)
end for
while True
msg = wait(1000, m.port)
if m.top.video = invalid
print "exiting"
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.video.position
If currentTime > 3 And not m.top.adPlaying
m.top.video.enableTrickPlay = true
End If
end while
End Sub
Function addCallbacks() as Void
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function
Function startCallback(ad as Object) as Void
print "Callback from SDK -- Start called - "
End Function
Function firstQuartileCallback(ad as Object) as Void
print "Callback from SDK -- First quartile called - "
End Function
Function midpointCallback(ad as Object) as Void
print "Callback from SDK -- Midpoint called - "
End Function
Function thirdQuartileCallback(ad as Object) as Void
print "Callback from SDK -- Third quartile called - "
End Function
Function completeCallback(ad as Object) as Void
print "Callback from SDK -- Complete called - "
End Function
Function errorCallback(error as Object) as Void
print "Callback from SDK -- Error called - "; error
m.errorState = True
End Function
स्किप किए जा सकने वाले विज्ञापनों के लिए सहायता जोड़ें (ज़रूरी नहीं)
स्किप किए जा सकने वाले विज्ञापन चलाए जा सकें, इसके लिए आपको IMA डीएआई SDK टूल के प्लेयर ऑब्जेक्ट में एक seek
तरीका जोड़ना होगा. यह ऑब्जेक्ट, वीडियो को फ़्लोटिंग-पॉइंट सेकंड में, तय की गई जगह पर प्रोग्रामैटिक तरीके से भेजता है.
स्किप किए जा सकने वाले विज्ञापनों के लिए, आपको अनुरोध में adUiNode
को सेट करना होगा.
Sdk.xml
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.seek = Function(timeSeconds as Float)
print "---- SDK requested seek to ----" ; timeSeconds
m.top.video.seekMode = "accurate"
m.top.video.seek = timeSeconds
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function