IMA SDK ช่วยให้การผสานรวมโฆษณามัลติมีเดียในเว็บไซต์และแอปของคุณทำได้โดยง่าย IMA SDK สามารถ ส่งคำขอโฆษณาจาก เซิร์ฟเวอร์โฆษณาที่ปฏิบัติตามข้อกำหนดของ VAST และจัดการการเล่นโฆษณาในแอปของคุณ ด้วย IMA DAI SDK แอปจะสร้าง คำขอสตรีมสำหรับโฆษณาและวิดีโอเนื้อหา ไม่ว่าจะเป็น VOD หรือเนื้อหาสด จากนั้น SDK จะแสดงผลลัพธ์ สตรีมวิดีโอแบบรวม คุณจึงไม่ต้องคอยจัดการสลับเปลี่ยนระหว่างโฆษณากับเนื้อหาวิดีโอ ภายในแอป
เลือกโซลูชัน DAI ที่คุณสนใจ
DAI บริการเต็มรูปแบบ
คู่มือนี้สาธิตวิธีผสานรวม IMA DAI SDK เข้ากับโปรแกรมเล่นวิดีโอแบบง่าย แอป หากคุณต้องการดูหรือติดตามไปพร้อมกับตัวอย่างที่สมบูรณ์ การผสานรวม ให้ดาวน์โหลดฟังก์ชัน ตัวอย่างจาก GitHub
ภาพรวม IMA DAI
การติดตั้งใช้งาน IMA DAI เกี่ยวข้องกับองค์ประกอบหลักของ SDK 2 อย่างดังที่แสดงใน คู่มือ
StreamRequest
: ออบเจ็กต์ที่กำหนดคำขอสตรีม คำขอสตรีมจะเป็นวิดีโอออนดีมานด์หรือแบบสดก็ได้ สตรีม คำขอระบุรหัสเนื้อหา รวมทั้งคีย์ API หรือโทเค็นการตรวจสอบสิทธิ์ และอื่นๆ พารามิเตอร์StreamManager
: ออบเจ็กต์ที่จัดการสตรีมการแทรกโฆษณาแบบไดนามิกและการโต้ตอบกับแบ็กเอนด์ DAI เครื่องมือจัดการสตรีมยังจัดการคําสั่ง ping ในการติดตาม รวมถึงส่งต่อเหตุการณ์ของสตรีมและโฆษณาไปยัง ผู้เผยแพร่โฆษณา
ข้อกำหนดเบื้องต้น
- อ่านหน้าความเข้ากันได้ของเราเพื่อตรวจสอบว่าระบบรองรับ Use Case ที่คุณต้องการ
- ดาวน์โหลดโปรแกรมเล่นตัวอย่างของ Roku โค้ด
- ปรับใช้โค้ดโปรแกรมเล่นตัวอย่างไปยังอุปกรณ์ Roku เพื่อยืนยันว่า การตั้งค่าการพัฒนาทำงานอยู่
เล่นวิดีโอ
โปรแกรมเล่นวิดีโอตัวอย่างที่มีให้จะเล่นวิดีโอเนื้อหานอกกล่อง ทำให้ใช้งานได้ โปรแกรมเล่นตัวอย่างไปยังโปรแกรมเล่นของ Roku เพื่อให้แน่ใจว่าสภาพแวดล้อมในการพัฒนาซอฟต์แวร์ของคุณเป็นแบบ ตั้งค่าอย่างเหมาะสม
เปลี่ยนโปรแกรมเล่นวิดีโอเป็นโปรแกรมเล่นสตรีม IMA DAI
ทำตามขั้นตอนต่อไปนี้เพื่อใช้งานโปรแกรมเล่นสตรีม
สร้าง Sdk.xml
เพิ่มไฟล์ใหม่ลงในการฉายภาพควบคู่ไปกับ MainScene.xml
ที่มีชื่อว่า Sdk.xml
และเพิ่มต้นแบบต่อไปนี้
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
' Your code goes here.
]]>
</script>
</component>
คุณต้องแก้ไขทั้งสองไฟล์นี้ตลอดทั้งคู่มือนี้
โหลดเฟรมเวิร์กโฆษณาของ Roku
IMA DAI SDK ขึ้นอยู่กับเฟรมเวิร์กโฆษณาของ Roku หากต้องการโหลดเฟรมเวิร์ก
เพิ่มข้อมูลต่อไปนี้ลงใน manifest
และ Sdk.xml
:
ประจักษ์
bs_libs_required=roku_ads_lib,googleima3
Sdk.xml
Library "Roku_Ads.brs"
Library "IMA3.brs"
โหลด IMA DAI SDK
ขั้นตอนแรกในการโหลดสตรีมการแทรกโฆษณาแบบไดนามิก IMA คือการโหลด และ เริ่มต้น IMA DAI SDK รายการต่อไปนี้จะโหลดสคริปต์ IMA DAI SDK
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
</interface>
...
Sub init()
m.top.functionName = "runThread"
End Sub
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
End Sub
Sub loadSdk()
If m.sdk = invalid
m.sdk = New_IMASDK()
End If
m.top.sdkLoaded = true
End Sub
ตอนนี้ให้เริ่มงานนี้ใน MainScene.xml
และนำการโทรออกเพื่อโหลดเนื้อหา
สตรีม
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
m.sdkTask.control = "RUN"
end function
Sub onSdkLoaded(message as Object)
print "----- onSdkLoaded --- control ";message
End Sub
Sub onSdkLoadedError(message as Object)
print "----- errors in the sdk loading process --- ";message
End Sub
สร้างโปรแกรมเล่นสตรีม IMA
ถัดไป คุณจะต้องใช้ roVideoScreen
ที่มีอยู่เพื่อสร้างสตรีม IMA
โปรแกรมเล่นวิดีโอ สตรีมเพลเยอร์นี้ใช้วิธีการเรียกกลับ 3 วิธี ได้แก่ loadUrl
adBreakStarted
และ adBreakEnded
และให้ปิดใช้ Trick Play เมื่อสตรีมด้วย
โหลดแล้ว วิธีนี้ช่วยป้องกันไม่ให้ผู้ใช้ข้ามโฆษณาตอนต้นได้ทันทีที่
ก่อนที่เหตุการณ์เริ่มต้นของช่วงพักโฆษณาจะเริ่มทำงาน
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
</interface>
...
Sub setupVideoPlayer()
sdk = m.sdk
m.player = sdk.createPlayer()
m.player.top = m.top
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function
m.player.adBreakEnded = Function(adBreakInfo as Object)
print "---- Ad Break Ended ---- "
m.top.adPlaying = False
m.top.video.enableTrickPlay = true
End Function
End Sub
สร้างและดำเนินการกับคำขอสตรีม
เมื่อมีโปรแกรมเล่นสตรีมแล้ว คุณจะสร้างและดำเนินการกับคำขอสตรีมได้
ตัวอย่างนี้มีข้อมูลสำหรับสตรีมแบบสดและสตรีม VOD ใช้ VOD
สตรีมได้ แต่คุณใช้ฟีเจอร์สดแทนได้โดยเปลี่ยน selectedStream
จาก
m.testVodStream
ถึง m.testLiveStream
เพื่อให้รองรับ AdUI เช่น ไอคอนตัวเลือกโฆษณาอื่นๆ คุณจะต้อง การอ้างอิงไปยังโหนดที่มีวิดีโอเนื้อหาของคุณซึ่งเป็นส่วนหนึ่งของคำขอ
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testLiveStream = {
title: "Livestream",
assetKey: "sN_IYUG8STe1ZzhIIE_ksA",
apiKey: "",
type: "live"
}
m.testVodStream = {
title: "VOD stream"
contentSourceId: "2548831",
videoId: "tears-of-steel",
apiKey: "",
type: "vod"
}
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
<field id="streamData" type="assocarray" />
<field id="streamManagerReady" type="Boolean" />
</interface>
...
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
End Sub
Sub loadStream()
sdk = m.sdk
sdk.initSdk()
setupVideoPlayer()
request = {}
streamData = m.top.streamData
if streamData.type = "live"
request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey)
else if streamData.type = "vod"
request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey)
else
request = sdk.CreateStreamRequest()
end if
request.player = m.player
request.videoObject = m.top.video
' Required to support UI elements for 'Why This Ad?' and skippability
request.adUiNode = m.top.video
requestResult = sdk.requestStream(request)
If requestResult <> Invalid
print "Error requesting stream ";requestResult
Else
m.streamManager = Invalid
While m.streamManager = Invalid
sleep(50)
m.streamManager = sdk.getStreamManager()
End While
If m.streamManager = Invalid or m.streamManager["type"] <> Invalid or m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "error ";m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
Else
m.top.streamManagerReady = True
addCallbacks()
m.streamManager.start()
End If
End If
End Sub
เพิ่ม Listener เหตุการณ์และเริ่มสตรีม
หลังจากขอสตรีมแล้ว ก็เหลือเพียงไม่กี่อย่างที่ต้องทำ คือเพิ่มกิจกรรม Listener เพื่อติดตามความคืบหน้าของโฆษณา เริ่มสตรีม และส่งต่อข้อความของ Roku ไปยัง SDK
MainScene.xml
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.observeField("urlData", "urlLoadRequested")
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sub urlLoadRequested(message as Object)
print "Url Load Requested ";message
data = message.getData()
playStream(data.manifest)
End Sub
Sub playStream(url as Object)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.url = url
vidContent.title = m.videoTitle
vidContent.streamformat = "hls"
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
End Sub
Sdk.xml
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
If m.top.streamManagerReady
runLoop()
End If
End Sub
Sub runLoop()
m.top.video.timedMetaDataSelectionKeys = ["*"]
m.port = CreateObject("roMessagePort")
' Listen to all fields.
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
fields = m.top.video.getFields()
for each field in fields
m.top.video.observeField(field, m.port)
end for
while True
msg = wait(1000, m.port)
if m.top.video = invalid
print "exiting"
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.video.position
If currentTime > 3 And not m.top.adPlaying
m.top.video.enableTrickPlay = true
End If
end while
End Sub
Function addCallbacks() as Void
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function
Function startCallback(ad as Object) as Void
print "Callback from SDK -- Start called - "
End Function
Function firstQuartileCallback(ad as Object) as Void
print "Callback from SDK -- First quartile called - "
End Function
Function midpointCallback(ad as Object) as Void
print "Callback from SDK -- Midpoint called - "
End Function
Function thirdQuartileCallback(ad as Object) as Void
print "Callback from SDK -- Third quartile called - "
End Function
Function completeCallback(ad as Object) as Void
print "Callback from SDK -- Complete called - "
End Function
Function errorCallback(error as Object) as Void
print "Callback from SDK -- Error called - "; error
m.errorState = True
End Function
เพิ่มการรองรับโฆษณาที่ข้ามได้ (ไม่บังคับ)
หากต้องการรองรับโฆษณาแบบข้ามได้ คุณต้องเพิ่มเมธอด seek
ลงใน
โปรแกรมเล่นของ IMA DAI SDK
ที่ค้นหาวิดีโอไปยังตำแหน่งที่ระบุในแบบเป็นโปรแกรม
จำนวนวินาทีที่จุดลอยตัว
ในการสนับสนุนโฆษณาแบบข้ามได้ คุณต้องตรวจสอบว่าคุณได้ตั้งค่า
adUiNode
ในคำขอ
Sdk.xml
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.seek = Function(timeSeconds as Float)
print "---- SDK requested seek to ----" ; timeSeconds
m.top.video.seekMode = "accurate"
m.top.video.seek = timeSeconds
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function