ערכות IMA SDK מאפשרות לכם לשלב בקלות מודעות מולטימדיה באתרים ובאפליקציות שלכם. ערכות IMA SDK יכולות לשלוח בקשה להצגת מודעות מכל שרת מודעות שתואם ל-VAST, ולנהל את הפעלת המודעות באפליקציות שלך. בעזרת ערכות IMA DAI SDK, אפליקציות שולחות בקשה לשידור וידאו של מודעה ותוכן – VOD או תוכן בשידור חי. לאחר מכן, ה-SDK יחזיר שידור וידאו משולב, כך שלא יהיה צורך לנהל את המעבר בין מודעות וידאו בתוכן לבין מודעות וידאו בתוך האפליקציה.
איך בוחרים את פתרון DAI שמעניין אתכם
DAI בשירות מלא
במדריך הזה נדגים איך לשלב את IMA DAI SDK באפליקציה פשוטה של נגן וידאו. אם אתם רוצים לצפות בהטמעה מלאה לדוגמה או לעקוב אחריה, אפשר להוריד את הדוגמה הבסיסית מ-GitHub.
סקירה כללית של IMA DAI
כדי להטמיע IMA DAI יש שני רכיבים עיקריים של ה-SDK, כפי שמודגם במדריך הזה:
StreamRequest
: אובייקט שמגדיר בקשה של מקור נתונים. הבקשות לשידור יכולות להיות לווידאו על פי דרישה (VOD) או לשידורים חיים. הבקשות מציינות את מזהה התוכן, וגם מפתח API או אסימון אימות ופרמטרים נוספים.StreamManager
: אובייקט שמטפל בשידורים של הוספת מודעה דינמית ובאינטראקציות עם הקצה העורפי של הטמעת מודעות דינמיות (DAI). מנהל הסטרימינג מטפל גם במעקב אחר פינגים ומעביר אירועי מודעות ושידורים חיים.
דרישות מוקדמות
- מומלץ לקרוא את דף התאימות שלנו כדי לוודא שיש תמיכה בתרחיש לדוגמה הרצוי.
- מורידים את קוד הנגן לדוגמה של Roku
- פורסים את קוד הנגן לדוגמה במכשיר Roku כדי לוודא שהגדרת הפיתוח פועלת.
הפעלת הסרטון
נגן הווידאו לדוגמה שסופק מפעיל סרטון תוכן מחוץ לאריזה. פורסים את הנגן לדוגמה לנגן Roku כדי לוודא שסביבת הפיתוח מוגדרת בצורה נכונה.
הפיכת נגן הווידאו שלך לנגן סטרימינג של IMA DAI
כדי להטמיע נגן סטרימינג, מבצעים את השלבים הבאים.
יצירת Sdk.xml
מוסיפים לפרויקט קובץ חדש לצד MainScene.xml
בשם Sdk.xml
ומוסיפים את התבנית הבאה:
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
' Your code goes here.
]]>
</script>
</component>
צריך לערוך את שני הקבצים האלה במדריך הזה.
טעינת Roku Advertising Framework
IMA DAI SDK תלוי ב-Roku Advertising Framework. כדי לטעון את ה-framework, מוסיפים את קטעי הקוד הבאים ל-manifest
ול-Sdk.xml
:
מניפסט
bs_libs_required=roku_ads_lib,googleima3
Sdk.xml
Library "Roku_Ads.brs"
Library "IMA3.brs"
טעינת IMA DAI SDK
השלב הראשון בטעינת הסטרימינג של IMA DAI SDK הוא לטעון ולאתחל את ה-IMA DAI SDK. קטע זה טוען את הסקריפט של IMA DAI SDK.
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
</interface>
...
Sub init()
m.top.functionName = "runThread"
End Sub
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
End Sub
Sub loadSdk()
If m.sdk = invalid
m.sdk = New_IMASDK()
End If
m.top.sdkLoaded = true
End Sub
עכשיו צריך להתחיל את המשימה הזו ב-MainScene.xml
ולהסיר את הקריאה לטעינת מקור התוכן.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
m.sdkTask.control = "RUN"
end function
Sub onSdkLoaded(message as Object)
print "----- onSdkLoaded --- control ";message
End Sub
Sub onSdkLoadedError(message as Object)
print "----- errors in the sdk loading process --- ";message
End Sub
יצירת נגן זרם IMA
לאחר מכן, עליכם להשתמש ב-roVideoScreen
הקיים כדי ליצור נגן IMA של סטרימינג. בנגן הסטרימינג הזה מוטמעות שלוש שיטות לקריאה חוזרת (callback): loadUrl
, adBreakStarted
ו-adBreakEnded
. בנוסף, תשביתו את הפעלת הטריקים כשהשידור נטען. כך המשתמשים לא יכולים לדלג על מודעה לפני סרטון ברגע שהיא מתחילה, לפני ההפעלה של האירוע 'הפסקה למודעות'.
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
</interface>
...
Sub setupVideoPlayer()
sdk = m.sdk
m.player = sdk.createPlayer()
m.player.top = m.top
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function
m.player.adBreakEnded = Function(adBreakInfo as Object)
print "---- Ad Break Ended ---- "
m.top.adPlaying = False
m.top.video.enableTrickPlay = true
End Function
End Sub
יצירה וביצוע של בקשה לשידור נתונים
עכשיו, כשיש לכם נגן סטרימינג, אתם יכולים ליצור ולהפעיל בקשה לשידור.
בדוגמה הזו יש נתונים לגבי שידור חי ו-VOD. נעשה שימוש בשידור של ה-VOD, אבל אם רוצים לעבור לשידור חי במקום זאת, אפשר לשנות את selectedStream
מ-m.testVodStream
ל-m.testLiveStream
.
כדי שתהיה לכם אפשרות לתמוך ב-AdUI, למשל סמלים של בחירת מודעות, צריך להעביר מהבקשה גם הפניה לצומת שמכיל את הסרטון בתוכן שלכם.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testLiveStream = {
title: "Livestream",
assetKey: "sN_IYUG8STe1ZzhIIE_ksA",
apiKey: "",
type: "live"
}
m.testVodStream = {
title: "VOD stream"
contentSourceId: "2548831",
videoId: "tears-of-steel",
apiKey: "",
type: "vod"
}
loadImaSdk()
end function
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sdk.xml
<interface>
<field id="sdkLoaded" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="video" type="Node" />
<field id="streamData" type="assocarray" />
<field id="streamManagerReady" type="Boolean" />
</interface>
...
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
End Sub
Sub loadStream()
sdk = m.sdk
sdk.initSdk()
setupVideoPlayer()
request = {}
streamData = m.top.streamData
if streamData.type = "live"
request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey)
else if streamData.type = "vod"
request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey)
else
request = sdk.CreateStreamRequest()
end if
request.player = m.player
request.videoObject = m.top.video
' Required to support UI elements for 'Why This Ad?' and skippability
request.adUiNode = m.top.video
requestResult = sdk.requestStream(request)
If requestResult <> Invalid
print "Error requesting stream ";requestResult
Else
m.streamManager = Invalid
While m.streamManager = Invalid
sleep(50)
m.streamManager = sdk.getStreamManager()
End While
If m.streamManager = Invalid or m.streamManager["type"] <> Invalid or m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "error ";m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
Else
m.top.streamManagerReady = True
addCallbacks()
m.streamManager.start()
End If
End If
End Sub
הוספת פונקציות event listener והפעלת השידור
אחרי שמבקשים להפעיל את הסטרימינג, נשארו רק כמה דברים לעשות: להוסיף מאזיני אירועים כדי לעקוב אחרי ההתקדמות של המודעות, להתחיל את השידור ולהעביר הודעות מ-Roku ל-SDK.
MainScene.xml
function loadImaSdk() as void
m.sdkTask = createObject("roSGNode", "imasdk")
m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
m.sdkTask.observeField("errors", "onSdkLoadedError")
selectedStream = m.testVodStream
m.videoTitle = selectedStream.title
m.sdkTask.streamData = selectedStream
m.sdkTask.observeField("urlData", "urlLoadRequested")
m.sdkTask.video = m.video
m.sdkTask.control = "RUN"
end function
Sub urlLoadRequested(message as Object)
print "Url Load Requested ";message
data = message.getData()
playStream(data.manifest)
End Sub
Sub playStream(url as Object)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.url = url
vidContent.title = m.videoTitle
vidContent.streamformat = "hls"
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
End Sub
Sdk.xml
Sub runThread()
if not m.top.sdkLoaded
loadSdk()
End If
if not m.top.streamManagerReady
loadStream()
End If
If m.top.streamManagerReady
runLoop()
End If
End Sub
Sub runLoop()
m.top.video.timedMetaDataSelectionKeys = ["*"]
m.port = CreateObject("roMessagePort")
' Listen to all fields.
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
fields = m.top.video.getFields()
for each field in fields
m.top.video.observeField(field, m.port)
end for
while True
msg = wait(1000, m.port)
if m.top.video = invalid
print "exiting"
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.video.position
If currentTime > 3 And not m.top.adPlaying
m.top.video.enableTrickPlay = true
End If
end while
End Sub
Function addCallbacks() as Void
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function
Function startCallback(ad as Object) as Void
print "Callback from SDK -- Start called - "
End Function
Function firstQuartileCallback(ad as Object) as Void
print "Callback from SDK -- First quartile called - "
End Function
Function midpointCallback(ad as Object) as Void
print "Callback from SDK -- Midpoint called - "
End Function
Function thirdQuartileCallback(ad as Object) as Void
print "Callback from SDK -- Third quartile called - "
End Function
Function completeCallback(ad as Object) as Void
print "Callback from SDK -- Complete called - "
End Function
Function errorCallback(error as Object) as Void
print "Callback from SDK -- Error called - "; error
m.errorState = True
End Function
הוספת תמיכה במודעות ניתנות לדילוג (אופציונלי)
כדי לתמוך במודעות ניתנות לדילוג, צריך להוסיף שיטה seek
לאובייקט נגן של IMA DAI SDK, שמחפש באופן פרוגרמטי את הסרטון למיקום שצוין, בשניות על נקודה צפה (floating-point).
כדי לתמוך במודעות שניתן לדלג עליהן, צריך גם לוודא שהגדרתם את adUiNode
בבקשה.
Sdk.xml
m.player.loadUrl = Function(urlData)
m.top.video.enableTrickPlay = false
m.top.urlData = urlData
End Function
m.player.seek = Function(timeSeconds as Float)
print "---- SDK requested seek to ----" ; timeSeconds
m.top.video.seekMode = "accurate"
m.top.video.seek = timeSeconds
End Function
m.player.adBreakStarted = Function(adBreakInfo as Object)
print "---- Ad Break Started ---- "
m.top.adPlaying = True
m.top.video.enableTrickPlay = false
End Function