تُسهل حزم تطوير البرامج لإعلانات الوسائط التفاعلية دمج إعلانات الوسائط المتعددة في مواقعك الإلكترونية وتطبيقاتك. ويمكن أن تطلب حِزم تطوير البرامج لإعلانات الوسائط التفاعلية إعلانات من أي خادم إعلانات متوافق مع VAST وإدارة تشغيل الإعلانات في تطبيقاتك. باستخدام حِزم تطوير البرامج لإدراج إعلان ديناميكي لإعلانات الوسائط التفاعلية، تطلب التطبيقات بث الفيديو الإعلاني والمحتوى، سواء كان فيديو عند الطلب أو محتوى مباشرًا. وبعد ذلك، تعرض حزمة تطوير البرامج (SDK) بث فيديو مجمّعًا، حتى لا تضطر إلى إدارة التبديل بين الإعلان وفيديو المحتوى داخل تطبيقك.
اختيار حل DAI الذي يهمّك
يوضّح هذا الدليل كيفية تشغيل بث مباشر أو إعلان فيديو عند الطلب لعرض إعلانات DAI باستخدام حزمة تطوير البرامج لإدراج إعلان ديناميكي لإعلانات الوسائط التفاعلية لنظام Roku.
نظرة عامة على عرض لوحة الإعلانات الديناميكية على شبكة البحث لإعلانات الوسائط التفاعلية
يتضمّن تنفيذ عرض الإعلانات المتسلسلة باستخدام ميزة DAI لإعلانات الوسائط التفاعلية مكوّنَين رئيسيَّين لحزمة تطوير البرامج (SDK) هو موضّحان في هذا الدليل:
StreamRequest.createPodLiveStreamRequest()
/StreamRequest.createPodVodStreamRequest()
: ينشئ كائنًا يحدّد طلب بث إلى خوادم الإعلانات في Google. تحدّد هذه الطلبات رمز شبكة، تتطلب Pod Liveima.StreamRequest
أيضًا مفتاح مادة عرض مخصصًا ومفتاح واجهة برمجة تطبيقات اختياري.StreamManager
: كائن يعالج الاتصال بين بث الفيديو وحزمة تطوير البرامج لإدراج إعلان ديناميكي لإعلانات الوسائط التفاعلية، مثل تنشيط إشعارات التتبّع وإعادة توجيه أحداث البث إلى الناشر.
بالإضافة إلى ذلك، يجب تقديم طلب إلى خادم معالجة البيانات لاسترداد بيانات البث لكي يعرضها تطبيقك. قد تختلف العملية الدقيقة من شريك تقنية الفيديو (VTP) إلى VTP.
المتطلبات الأساسية
- يُرجى الاطّلاع على صفحة التوافق للتأكد من توافق حالة الاستخدام المقصودة.
- نزِّل نموذج رمز مشغّل Roku.
- انشر نموذج رمز مشغّل الفيديو على جهاز Roku للتحقق من نجاح إعداد تطوير البرامج.
تشغيل الفيديو
يتم تشغيل فيديو محتوى بطريقة غير تقليدية من خلال نموذج مشغّل الفيديو. انشر نموذج المشغّل على جهاز Roku لضمان إعداد بيئة التطوير بشكل صحيح.
تحويل مشغّل الفيديو إلى مشغّل بث لإعلانات الوسائط التفاعلية (IMA)
اتّبِع الخطوات التالية لتشغيل مشغّل بث:
إنشاء Sdk.xml
أضِف ملفًا جديدًا إلى مشروعك إلى جانب MainScene.xml
باسم Sdk.xml
، ثم أضِف النص النموذجي التالي:
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
' Your code goes here.
]]>
</script>
</component>
يجب تعديل هذين الملفين (MainScene.xml
وSdk.xml
) في
هذا الدليل.
تحميل إطار عمل حزمة تطوير البرامج لإعلانات الوسائط التفاعلية
لتحميل إطار العمل، أضِف ما يلي إلى manifest
وSdk.xml
:
بيان
bs_libs_required=googleima3
Sdk.xml
<?xml version = "1.0" encoding = "utf-8" ?>
<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
Library "IMA3.brs"
]]>
</script>
</component>
إعداد حزمة تطوير البرامج لإعلانات الوسائط التفاعلية
تتمثل الخطوة الأولى لتحميل ساحة مشاركات الإدراج الديناميكي لإعلانات الوسائط التفاعلية في تحميل وتهيئة حزمة تطوير البرامج لإعلانات الوسائط التفاعلية. يؤدي ما يلي إلى تهيئة النص البرمجي لأداة تطوير البرامج لإعلانات الوسائط التفاعلية.
Sdk.xml
<?xml version="1.0" encoding="utf-8" ?>
<component name="IMASDKTask" extends="Task">
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
</interface>
<script type = "text/brightscript">
<![CDATA[
Library "IMA3.brs"
sub init()
m.top.functionName = "runThread"
end sub
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
end sub
sub initializeIMASDK()
if m.sdk = invalid
m.sdk = New_IMASDK()
end if
m.top.IMASDKInitialized = true
end sub
]]>
</script>
</component>
ابدأ الآن هذه المهمة في MainScene.xml
وأزِل الطلب لتحميل بث المحتوى.
MainScene.xml
<?xml version="1.0" encoding="utf-8" ?>
<component extends="Scene" initialFocus="myVideo" name="MainScene">
<script type="text/brightscript">
<![CDATA[
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
runIMASDKTask()
end function
function runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.IMASDKTask.control = "RUN"
end function
sub handleIMASDKInitialized()
' Follow your manifest manipulator (VTP) documentation to register a user
' streaming session if needed.
end sub
sub handleIMASDKErrors(message as object)
print "------ IMA SDK failed ------"
if message <> invalid and message.getData() <> invalid
print "IMA SDK Error ";message.getData()
end if
end sub
]]>
</script>
<children>
<Video height="720" id="myVideo" visible="false" width="1280"/>
</children>
</component>
إنشاء مشغّل بث إعلانات الوسائط التفاعلية
بعد ذلك، عليك استخدام roVideoScreen
الحالي لإنشاء مشغّل بث لإعلانات الوسائط التفاعلية.
عرض لوحات البث المباشر
بالنسبة إلى أحداث البث المباشر، يتّبع مشغِّل البث هذا ثلاث طرق لرد الاتصال:
streamInitialized
وadBreakStarted
وadBreakEnded
.
أوقِف أيضًا أسلوب اللعب بالخدعة عند تحميل البث. يمنع ذلك المستخدمين من تخطّي إعلان ما قبل التشغيل فور بدئه، أو قبل بدء حدث الفاصل الإعلاني.
Sdk.xml
<?xml version="1.0" encoding="utf-8" ?>
<component name="IMASDKTask" extends="Task">
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="videoNode" type="Node" />
</interface>
<script type="text/brightscript">
...
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
end sub
...
sub initializeIMASDK()
if m.ima = invalid
ima = New_IMASDK()
ima.initSdk()
m.ima = ima
end if
m.top.IMASDKInitialized = true
end sub
sub setupPlayerCallbacks()
m.player = m.ima.createPlayer()
m.player.top = m.top
m.player.streamInitialized = function(urlData)
m.top.videoNode.enableTrickPlay = false
m.top.urlData = urlData
end function
m.player.adBreakStarted = function(adBreakInfo)
print "------ Ad break started ------"
m.top.adPlaying = true
m.top.videoNode.enableTrickPlay = false
end function
m.player.adBreakEnded = function(adBreakInfo)
print "------ Ad break ended ------"
m.top.adPlaying = false
m.top.videoNode.enableTrickPlay = true
end function
end sub
</script>
...
</component>
عرض لوحة بث عند الطلب
بالنسبة إلى أحداث بث الفيديو عند الطلب، يستخدم مشغِّل البث هذا أربع طرق لرد الاتصال:
streamInitialized
وloadUrl
وadBreakStarted
وadBreakEnded
. ضمن
"معاودة الاتصال" باستخدام "streamInitialized
"، احرص على الاتصال برقم
"StreamManager.loadThirdPartyStream()
". ولن يؤدي عدم الالتزام بذلك إلى تشغيل دالة loadUrl
في حزمة تطوير البرامج (SDK).
في هذه الخطوة، يجب أيضًا طلب عنوان URL للبث من شريك تكنولوجيا الفيديو
(VTP) الذي يحتوي على معرّف بث تم الحصول عليه في loadAdPodStream()
. بعد ذلك، استدعِ "StreamManager.loadThirdPartyStream()
" مع بيان مجموعة الإعلانات المتسلسلة وأي
عناوين فرعية يعرضها VTP.
أوقِف أيضًا أسلوب اللعب بالخدعة عند تحميل البث. يمنع ذلك المستخدمين من تخطّي إعلان ما قبل التشغيل فور بدئه، أو قبل بدء حدث الفاصل الإعلاني.
Sdk.xml
<?xml version="1.0" encoding="utf-8" ?>
<component name="IMASDKTask" extends="Task">
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="adStitchedStreamInfo" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="videoNode" type="Node" />
<field id="streamParameters" type="assocarray" />
</interface>
<script type="text/brightscript">
...
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
end sub
...
sub initializeIMASDK()
if m.ima = invalid
ima = New_IMASDK()
ima.initSdk()
m.ima = ima
end if
m.top.IMASDKInitialized = true
end sub
sub loadThirdPartyStream(adStitchedManifest as string, subtitleConfig as dynamic)
m.streamManager.loadThirdPartyStream(adStitchedManifest, subtitleConfig)
end sub
sub setupPlayerCallbacks()
m.player = m.ima.createPlayer()
m.player.top = m.top
m.player.streamInitialized = function(urlData)
adStitchedManifest = m.top.streamParameters.VTPManifest.replace("[[STREAMID]]", urlData.streamId)
loadThirdPartyStream(adStitchedManifest, m.top.streamParameters.subtitleConfig)
end function
m.player.loadUrl = function(streamInfo)
m.top.adStitchedStreamInfo = streamInfo
end function
m.player.adBreakStarted = function(adBreakInfo)
print "------ Ad break started ------"
m.top.adPlaying = true
m.top.videoNode.enableTrickPlay = false
end function
m.player.adBreakEnded = function(adBreakInfo)
print "------ Ad break ended ------"
m.top.adPlaying = false
m.top.videoNode.enableTrickPlay = true
end function
end sub
</script>
...
</component>
إنشاء وتنفيذ طلبات بث مباشر أو إعلانات متسلسلة عند الطلب
بعد توفُّر مشغّل بث، يمكنك إنشاء طلب بث وتنفيذه.
يحتوي هذا المثال على بيانات لتدفق عرض لوحات الإعلانات المتسلسلة المخزّنة في
m.testPodServingStream
.
عرض لوحات البث المباشر
في العنصر m.testPodServingStream
، خزِّن المَعلمات التي يحتاجها "مدير إعلانات Google" لتحديد مجموعة البث المعنيّة، مثل رمز شبكة ومفتاح مادة عرض مخصّص. يمكنك أيضًا تخزين عنوان URL للبيان المُستخدَم للوصول إلى خادم معالجة البيان. في هذه الحالة، يجب إضافة معرّف مصدر البيانات من Google
في عنوان URL الخاص بالبيان بعد إرجاع طلب البث.
ولدعم AdUI، مثل رموز "خيارات الإعلان"، عليك أيضًا تمرير مرجع إلى العقدة التي تحتوي على فيديو المحتوى كجزء من طلبك.
MainScene.xml
function init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testPodServingStream = {
title: "Test live stream for DAI Pod Serving",
assetKey: "test-live-stream",
networkCode: "your-network-code",
manifest: "https://.../master.m3u8?stream_id=[[STREAMID]]",
apiKey: ""
}
runIMASDKTask()
end function
function runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.IMASDKTask.control = "RUN"
end function
Sdk.xml
<interface>
<field id="IMASDKInitialized" type="Boolean" />
<field id="errors" type="stringarray" />
<field id="urlData" type="assocarray" />
<field id="adPlaying" type="Boolean" />
<field id="videoNode" type="Node" />
<field id="streamParameters" type="assocarray" />
</interface>
...
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
end sub
sub loadAdPodStream()
request = m.ima.CreatePodLiveStreamRequest(m.top.streamParameters.assetKey, m.top.streamParameters.networkCode, m.top.streamParameters.apiKey)
' Set the player object so that the request can trigger the player's
' callbacks at stream initialization or playback events.
request.player = m.player
' Set the video node for the IMA SDK to create ad UI as its child nodes.
request.adUiNode = m.top.video
requestResult = m.ima.requestStream(request)
if requestResult <> invalid
print "Error requesting stream ";requestResult
return
end if
m.streamManager = invalid
while m.streamManager = invalid
sleep(50)
m.streamManager = m.ima.getStreamManager()
end while
if m.streamManager = invalid
errors = CreateObject("roArray", 1, True)
invalidStreamManagerError = "Invalid stream manager"
print invalidStreamManagerError
errors.push(invalidStreamManagerError)
m.top.errors = errors
return
end if
if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "Stream request returns an error. " ; m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
return
end if
setupStreamManager()
m.streamManager.start()
end sub
عرض لوحة بث عند الطلب
في العنصر m.testPodServingStream
، ستخزِّن رمز الشبكة المستخدَم في
طلب البث، لكي يتمكّن "مدير إعلانات Google" من توفير رقم تعريف لمصدر البيانات. يمكنك أيضًا تخزين
عنوان URL للبيان المستخدَم للوصول إلى البيان الخاص بالمستخدم على خادم
معالجة البيان.
للتمكّن من دعم AdUI، مثل رموز خيارات الإعلان، عليك أيضًا تمرير مرجع إلى العقدة التي تحتوي على فيديو المحتوى كجزء من طلبك.
MainScene.xml
sub init()
m.video = m.top.findNode("myVideo")
m.video.notificationinterval = 1
m.testPodServingStream = {
title: "Pod Serving VOD Stream",
networkCode: "your-network-code",
VTPManifest: "https://.../manifest.m3u8?gam-stream-id=[[STREAMID]]",
subtitleConfig: []
}
runIMASDKTask()
end sub
sub runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.IMASDKTask.control = "RUN"
end sub
Sdk.xml
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
end sub
sub loadAdPodStream()
request = m.ima.CreatePodVodStreamRequest(m.top.streamParameters.networkCode)
' Set the player object so that the request can trigger the player
' callbacks at stream initialization or playback events.
request.player = m.player
' Set the video node for the IMA SDK to create ad UI as its child nodes.
request.adUiNode = m.top.video
requestResult = m.ima.requestStream(request)
if requestResult <> invalid
print "Error requesting stream ";requestResult
return
end if
m.streamManager = invalid
while m.streamManager = invalid
sleep(50)
m.streamManager = m.ima.getStreamManager()
end while
if m.streamManager = invalid
errors = CreateObject("roArray", 1, True)
invalidStreamManagerError = "Invalid stream manager"
print invalidStreamManagerError
errors.push(invalidStreamManagerError)
m.top.errors = errors
return
end if
if m.streamManager["type"] <> invalid and m.streamManager["type"] = "error"
errors = CreateObject("roArray", 1, True)
print "Stream request returns an error. " ; m.streamManager["info"]
errors.push(m.streamManager["info"])
m.top.errors = errors
return
end if
setupStreamManager()
m.streamManager.start()
end sub
إضافة أدوات معالجة الحدث وبدء البث
عرض لوحات البث المباشر
بعد طلب البث، لم يتبقَّ سوى خطوات قليلة: إضافة أدوات معالجة الحدث لتتبُّع مستوى تقدّم الإعلان وإعادة توجيه رسائل Roku إلى حزمة تطوير البرامج (SDK). من المهم إعادة توجيه جميع الرسائل إلى حزمة تطوير البرامج (SDK) لضمان تشغيل الإعلانات بشكل صحيح. ويؤدي عدم الالتزام بذلك إلى الإبلاغ عن مشاهدات الإعلان بشكل غير صحيح.
في هذه الخطوة، يمكنك أيضًا إضافة دالة لاستبدال وحدة الماكرو [[STREAMID]]
بمعرّف البث
وتمرير عنوان URL لطلب البيان المكتمل إلى مشغّل الفيديو.
تحصل عملية التنفيذ هذه على معرّف مصدر البيانات في هذه الخطوة، ولكن استنادًا إلى عملية دمج VTP، قد تكون متاحة قبل هذه الخطوة.
MainScene.xml
function runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")
m.sdkTask.control = "RUN"
end function
sub loadAdStitchedStream(message as object)
print "Ad pod stream information ";message
adPodStreamInfo = message.getData()
manifest = m.testPodservingStream.manifest.Replace("[[STREAMID]]", adPodStreamInfo.streamId)
playStream(manifest, adPodStreamInfo.format)
end sub
sub playStream(url as string, format as string)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.url = url
vidContent.title = m.testPodservingStream.title
vidContent.streamformat = format
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
end sub
Sdk.xml
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
if m.streamManager <> invalid
runLoop()
end if
end sub
sub runLoop()
m.top.videoNode.timedMetaDataSelectionKeys = ["*"]
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
m.port = CreateObject("roMessagePort")
m.top.videoNode.observeField("position", m.port)
m.top.videoNode.observeField("timedMetaData", m.port)
m.top.videoNode.observeField("timedMetaData2", m.port)
m.top.videoNode.observeField("state", m.port)
while True
msg = wait(1000, m.port)
if m.top.videoNode = invalid
print "exiting"
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.videoNode.position
if currentTime > 3 And not m.top.adPlaying
m.top.videoNode.enableTrickPlay = true
end if
end while
end sub
sub setupStreamManager()
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub
sub startCallback(ad as object)
print "Callback from SDK -- Start called - "
end sub
sub firstQuartileCallback(ad as object)
print "Callback from SDK -- First quartile called - "
end sub
sub midpointCallback(ad as object)
print "Callback from SDK -- Midpoint called - "
end sub
sub thirdQuartileCallback(ad as object)
print "Callback from SDK -- Third quartile called - "
end sub
sub completeCallback(ad as object)
print "Callback from SDK -- Complete called - "
end sub
function errorCallback(error as object)
print "Callback from SDK -- Error called - " ; error
m.errorState = True
end function
عرض لوحة بث عند الطلب
بعد طلب البث، لم يتبقَّ سوى خطوات قليلة: إضافة أدوات معالجة الحدث لتتبُّع مستوى تقدّم الإعلان وإعادة توجيه رسائل Roku إلى حزمة تطوير البرامج (SDK). من المهم إعادة توجيه جميع الرسائل إلى حزمة تطوير البرامج (SDK) لضمان التشغيل الصحيح للإعلان. وسيؤدي عدم الالتزام بذلك إلى الإبلاغ بشكل غير صحيح عن مشاهدات الإعلان.
MainScene.xml
sub runIMASDKTask()
m.IMASDKTask = createObject("roSGNode", "IMASDKTask")
m.IMASDKTask.streamParameters = m.testPodservingStream
m.IMASDKTask.videoNode = m.video
m.IMASDKTask.observeField("IMASDKInitialized", "handleIMASDKInitialized")
m.IMASDKTask.observeField("errors", "handleIMASDKErrors")
m.sdkTask.observeField("adStitchedStreamInfo", "loadAdStitchedStream")
m.sdkTask.control = "RUN"
end sub
sub loadAdStitchedStream(message as object)
print "Ad pod stream information ";message
adPodStreamInfo = message.getData()
end sub
sub playStream(url as string, format as string, subtitleConfig as object)
vidContent = createObject("RoSGNode", "ContentNode")
vidContent.title = m.testPodservingStream.title
vidContent.url = url
vidContent.subtitleConfig = subtitleConfig
vidContent.streamformat = format
m.video.content = vidContent
m.video.setFocus(true)
m.video.visible = true
m.video.control = "play"
m.video.EnableCookies()
end sub
Sdk.xml
sub runThread()
if not m.top.IMASDKInitialized
initializeIMASDK()
end if
setupPlayerCallbacks()
loadAdPodStream()
if m.streamManager <> invalid
runLoop()
end if
end sub
sub runLoop()
m.top.videoNode.timedMetaDataSelectionKeys = ["*"]
' IMPORTANT: Failure to listen to the position and timedmetadata fields
' could result in ad impressions not being reported.
m.port = CreateObject("roMessagePort")
m.top.videoNode.observeField("position", m.port)
m.top.videoNode.observeField("timedMetaData", m.port)
m.top.videoNode.observeField("timedMetaData2", m.port)
m.top.videoNode.observeField("state", m.port)
while True
msg = wait(1000, m.port)
if m.top.videoNode = invalid
exit while
end if
m.streamManager.onMessage(msg)
currentTime = m.top.videoNode.position
if currentTime > 3 and not m.top.adPlaying
m.top.videoNode.enableTrickPlay = true
end if
end while
end sub
sub setupStreamManager()
m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
end sub
sub startCallback(ad as object)
print "Callback from SDK -- Start called - "
end sub
sub firstQuartileCallback(ad as object)
print "Callback from SDK -- First quartile called - "
end sub
sub midpointCallback(ad as object)
print "Callback from SDK -- Midpoint called - "
end sub
sub thirdQuartileCallback(ad as object)
print "Callback from SDK -- Third quartile called - "
end sub
sub completeCallback(ad as object)
print "Callback from SDK -- Complete called - "
end sub
sub errorCallback(error as object)
print "Callback from SDK -- Error called - " ; error
m.errorState = True
end sub