इस पेज का अनुवाद Cloud Translation API से किया गया है.

IMA डीएआई SDK टूल का इस्तेमाल शुरू करना

IMA SDK आपकी वेबसाइटों और ऐप्लिकेशन में मल्टीमीडिया विज्ञापनों को इंटिग्रेट करना आसान बनाते हैं. IMA SDK ये काम कर सकते हैं किसी भी वेबसाइट या ऐप्लिकेशन से विज्ञापनों का अनुरोध करें वीएएसटी का पालन करने वाला विज्ञापन सर्वर और अपने ऐप्लिकेशन में विज्ञापन चलाने की सुविधा को मैनेज करना. IMA डीएआई SDK टूल की मदद से, ऐप्लिकेशन वीओडी या लाइव कॉन्टेंट, विज्ञापन और कॉन्टेंट वीडियो के लिए स्ट्रीम अनुरोध. इसके बाद, SDK टूल जोड़ी गई वीडियो स्ट्रीम की सुविधा मिलती है, ताकि आपको विज्ञापन और कॉन्टेंट वीडियो के बीच स्विच करने को मैनेज न करना पड़े शामिल हैं.

अपनी पसंद का डीएआई सलूशन चुनें

पूरी सेवा वाला डीएआई

इस गाइड में IMA डीएआई SDK टूल को एक आसान वीडियो प्लेयर में जोड़ने का तरीका बताया गया है है. अगर आपको पूरा सैंपल देखना या उसके साथ फ़ॉलो करना है इंटिग्रेशन, बुनियादी उदाहरण देखें.

IMA डीएआई की खास जानकारी

IMA डीएआई को लागू करने में, SDK टूल के दो मुख्य कॉम्पोनेंट शामिल होते हैं. इनके बारे में इसमें बताया गया है गाइड:

StreamRequest: एक ऑब्जेक्ट जो स्ट्रीम के अनुरोध के बारे में बताता है. स्ट्रीम के अनुरोध, मांग पर वीडियो या लाइव हो सकते हैं स्ट्रीम. अनुरोध, Content ID, एपीआई पासकोड या पुष्टि करने वाले टोकन वगैरह के बारे में बताते हैं पैरामीटर का इस्तेमाल करें.
StreamManager: एक ऐसा ऑब्जेक्ट जो डीएआई बैकएंड के साथ डाइनैमिक विज्ञापन इंसर्शन स्ट्रीम और इंटरैक्शन को हैंडल करता है. कॉन्टेंट बनाने स्ट्रीम मैनेजर, पिंग की जानकारी ट्रैक करने का काम भी करता है. साथ ही, लाइव स्ट्रीम और विज्ञापन इवेंट को प्रकाशक हैं.

ज़रूरी शर्तें

हमारे साथ काम करने के तरीके की जानकारी देने वाले पेज को पढ़ें और पक्का करें कि आपको जिस उदाहरण का इस्तेमाल करना है वह Google Pay के साथ काम करता है या नहीं.
हमारा Roku सैंपल प्लेयर डाउनलोड करें कोड
सैंपल प्लेयर कोड को Roku डिवाइस पर डिप्लॉय करके यह पुष्टि करें कि डेवलपमेंट सेट अप काम कर रहा है.

अपना वीडियो चलाएं

सैंपल वीडियो प्लेयर, कॉन्टेंट वीडियो को अलग-अलग तरह से चलाता है. डिप्लॉय करें नमूना प्लेयर को आपके Roku प्लेयर पर जोड़ सकते हैं, ताकि यह पक्का किया जा सके कि आपका डेवलपमेंट एनवायरमेंट सही तरीके से सेट अप होता है.

अपने वीडियो प्लेयर को IMA डीएआई स्ट्रीम प्लेयर में बदलें

स्ट्रीम प्लेयर लागू करने के लिए, यह तरीका अपनाएं.

Sdk.xml बनाएं

MainScene.xml के साथ अपने प्रोजेक्ट में Sdk.xml नाम की नई फ़ाइल जोड़ें, और ये बॉयलरप्लेट जोड़ दें:

Sdk.xml

<?xml version = "1.0" encoding = "utf-8" ?>

<component name = "imasdk" extends = "Task">
<interface>
</interface>
<script type = "text/brightscript">
<![CDATA[
  ' Your code goes here.
]]>
</script>
</component>

इस गाइड में आपको इन दोनों फ़ाइलों में बदलाव करना होगा.

Roku विज्ञापन फ़्रेमवर्क लोड करें

IMA डीएआई SDK टूल, Roku विज्ञापन फ़्रेमवर्क पर निर्भर करता है. फ़्रेमवर्क लोड करने के लिए, manifest और Sdk.xml में यह जोड़ें:

मेनिफ़ेस्ट

bs_libs_required=roku_ads_lib,googleima3

Sdk.xml

Library "Roku_Ads.brs"
Library "IMA3.brs"

IMA डीएआई SDK टूल लोड करें

IMA डाइनैमिक ऐड इंसर्शन स्ट्रीम लोड करने का पहला चरण है, लोड करना और IMA डीएआई SDK टूल शुरू किया जा सकता है. नीचे दी गई जानकारी, IMA डीएआई SDK टूल की स्क्रिप्ट को लोड करती है.

Sdk.xml

<interface>
  <field id="sdkLoaded" type="Boolean" />
  <field id="errors" type="stringarray" />
</interface>
...
Sub init()
  m.top.functionName = "runThread"
End Sub

Sub runThread()
  if not m.top.sdkLoaded
    loadSdk()
  End If
End Sub

Sub loadSdk()
    If m.sdk = invalid
      m.sdk = New_IMASDK()
    End If
    m.top.sdkLoaded = true
End Sub

अब MainScene.xml में यह टास्क शुरू करें. साथ ही, कॉन्टेंट लोड करने के लिए कॉल हटाएं स्ट्रीम.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  loadImaSdk()
end function

function loadImaSdk() as void
  m.sdkTask = createObject("roSGNode", "imasdk")
  m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
  m.sdkTask.observeField("errors", "onSdkLoadedError")

  m.sdkTask.control = "RUN"
end function

Sub onSdkLoaded(message as Object)
  print "----- onSdkLoaded --- control ";message
End Sub

Sub onSdkLoadedError(message as Object)
  print "----- errors in the sdk loading process --- ";message
End Sub

IMA स्ट्रीम प्लेयर बनाएं

इसके बाद, आपको IMA स्ट्रीम बनाने के लिए, अपने मौजूदा roVideoScreen का इस्तेमाल करना होगा प्लेयर. यह स्ट्रीम प्लेयर तीन कॉलबैक तरीके लागू करता है: loadUrl, adBreakStarted और adBreakEnded. साथ ही, स्ट्रीम करते समय ट्रिक प्ले को बंद करें लोड हो जाता है. इससे उपयोगकर्ता वीडियो शुरू होने से पहले विज्ञापन को स्किप नहीं कर सकते विज्ञापन के लिए ब्रेक शुरू होने वाला इवेंट चालू होने से पहले, शुरू होता है.

Sdk.xml

<interface>
  <field id="sdkLoaded" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="video" type="Node" />
</interface>
...
Sub setupVideoPlayer()
  sdk = m.sdk
  m.player = sdk.createPlayer()
  m.player.top = m.top
  m.player.loadUrl = Function(urlData)
    m.top.video.enableTrickPlay = false
    m.top.urlData = urlData
  End Function
  m.player.adBreakStarted = Function(adBreakInfo as Object)
    print "---- Ad Break Started ---- "
    m.top.adPlaying = True
    m.top.video.enableTrickPlay = false
  End Function
  m.player.adBreakEnded = Function(adBreakInfo as Object)
    print "---- Ad Break Ended ---- "
    m.top.adPlaying = False
    m.top.video.enableTrickPlay = true
  End Function
End Sub

स्ट्रीम का अनुरोध करना और उसे लागू करना

अब आपके पास स्ट्रीम प्लेयर है, तो स्ट्रीम का अनुरोध किया जा सकता है और उसे पूरा किया जा सकता है. इस उदाहरण में, लाइव स्ट्रीम और वीओडी (वीडियो ऑन डिमांड) स्ट्रीम का डेटा है. इसमें वीओडी (वीडियो ऑन डिमांड) का इस्तेमाल किया गया है स्ट्रीम कर सकते हैं, लेकिन selectedStream को बदलकर लाइव स्ट्रीम का इस्तेमाल कर सकते हैं: m.testLiveStream के लिए m.testVodStream.

AdUI, जैसे कि adChoices आइकॉन के साथ काम करने के लिए, आपको उस नोड का रेफ़रंस दें जिसमें आपके अनुरोध के हिस्से के तौर पर आपका कॉन्टेंट वीडियो है.

MainScene.xml

function init()
  m.video = m.top.findNode("myVideo")
  m.video.notificationinterval = 1
  m.testLiveStream = {
    title: "Livestream",
    assetKey: "sN_IYUG8STe1ZzhIIE_ksA",
    apiKey: "",
    type: "live"
  }
  m.testVodStream = {
    title: "VOD stream"
    contentSourceId: "2548831",
    videoId: "tears-of-steel",
    apiKey: "",
    type: "vod"
  }
  loadImaSdk()
end function

function loadImaSdk() as void
  m.sdkTask = createObject("roSGNode", "imasdk")
  m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
  m.sdkTask.observeField("errors", "onSdkLoadedError")

  selectedStream = m.testVodStream
  m.videoTitle = selectedStream.title
  m.sdkTask.streamData = selectedStream

  m.sdkTask.video = m.video
  m.sdkTask.control = "RUN"
end function

Sdk.xml

<interface>
  <field id="sdkLoaded" type="Boolean" />
  <field id="errors" type="stringarray" />
  <field id="urlData" type="assocarray" />
  <field id="adPlaying" type="Boolean" />
  <field id="video" type="Node" />
  <field id="streamData" type="assocarray" />
  <field id="streamManagerReady" type="Boolean" />
</interface>
...
Sub runThread()
  if not m.top.sdkLoaded
    loadSdk()
  End If
  if not m.top.streamManagerReady
    loadStream()
  End If
End Sub

Sub loadStream()
  sdk = m.sdk
  sdk.initSdk()
  setupVideoPlayer()

  request = {}
  streamData = m.top.streamData
  if streamData.type = "live"
    request = sdk.CreateLiveStreamRequest(streamData.assetKey, streamData.apiKey)
  else if streamData.type = "vod"
    request = sdk.CreateVodStreamRequest(streamData.contentSourceId, streamData.videoId, streamData.apiKey)
  else
    request = sdk.CreateStreamRequest()
  end if

  request.player = m.player
  request.videoObject = m.top.video
  ' Required to support UI elements for 'Why This Ad?' and skippability
  request.adUiNode = m.top.video

  requestResult = sdk.requestStream(request)
  If requestResult &lt;&gt; Invalid
    print "Error requesting stream ";requestResult
  Else
    m.streamManager = Invalid
    While m.streamManager = Invalid
      sleep(50)
      m.streamManager = sdk.getStreamManager()
    End While
    If m.streamManager = Invalid or m.streamManager["type"] &lt;&gt; Invalid or m.streamManager["type"] = "error"
      errors = CreateObject("roArray", 1, True)
      print "error ";m.streamManager["info"]
      errors.push(m.streamManager["info"])
      m.top.errors = errors
    Else
      m.top.streamManagerReady = True
      addCallbacks()
      m.streamManager.start()
    End If
  End If
End Sub

इवेंट लिसनर जोड़ें और स्ट्रीम शुरू करें

अपनी स्ट्रीम का अनुरोध करने के बाद, बस कुछ ही काम बचे हैं: इवेंट जोड़ें ताकि आपके विज्ञापन की प्रोग्रेस को ट्रैक किया जा सके, स्ट्रीम शुरू की जा सके, और Roku मैसेज फ़ॉरवर्ड किए जा सकें का इस्तेमाल किया है.

MainScene.xml

function loadImaSdk() as void
  m.sdkTask = createObject("roSGNode", "imasdk")
  m.sdkTask.observeField("sdkLoaded", "onSdkLoaded")
  m.sdkTask.observeField("errors", "onSdkLoadedError")

  selectedStream = m.testVodStream
  m.videoTitle = selectedStream.title
  m.sdkTask.streamData = selectedStream

  m.sdkTask.observeField("urlData", "urlLoadRequested")
  m.sdkTask.video = m.video
  m.sdkTask.control = "RUN"
end function

Sub urlLoadRequested(message as Object)
  print "Url Load Requested ";message
  data = message.getData()

  playStream(data.manifest)
End Sub

Sub playStream(url as Object)
  vidContent = createObject("RoSGNode", "ContentNode")
  vidContent.url = url
  vidContent.title = m.videoTitle
  vidContent.streamformat = "hls"
  m.video.content = vidContent
  m.video.setFocus(true)
  m.video.visible = true
  m.video.control = "play"
  m.video.EnableCookies()
End Sub

Sdk.xml

Sub runThread()
  if not m.top.sdkLoaded
    loadSdk()
  End If
  if not m.top.streamManagerReady
    loadStream()
  End If
  If m.top.streamManagerReady
    runLoop()
  End If
End Sub

Sub runLoop()
  m.top.video.timedMetaDataSelectionKeys = ["*"]

  m.port = CreateObject("roMessagePort")

  ' Listen to all fields.

  ' IMPORTANT: Failure to listen to the position and timedmetadata fields
  ' could result in ad impressions not being reported.
  fields = m.top.video.getFields()
  for each field in fields
    m.top.video.observeField(field, m.port)
  end for

  while True
    msg = wait(1000, m.port)
    if m.top.video = invalid
      print "exiting"
      exit while
    end if

    m.streamManager.onMessage(msg)
    currentTime = m.top.video.position
    If currentTime > 3 And not m.top.adPlaying
       m.top.video.enableTrickPlay = true
    End If
  end while
End Sub

Function addCallbacks() as Void
  m.streamManager.addEventListener(m.sdk.AdEvent.ERROR, errorCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
  m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)
End Function

Function startCallback(ad as Object) as Void
  print "Callback from SDK -- Start called - "
End Function

Function firstQuartileCallback(ad as Object) as Void
  print "Callback from SDK -- First quartile called - "
End Function

Function midpointCallback(ad as Object) as Void
  print "Callback from SDK -- Midpoint called - "
End Function

Function thirdQuartileCallback(ad as Object) as Void
  print "Callback from SDK -- Third quartile called - "
End Function

Function completeCallback(ad as Object) as Void
  print "Callback from SDK -- Complete called - "
End Function

Function errorCallback(error as Object) as Void
  print "Callback from SDK -- Error called - "; error
  m.errorState = True
End Function

स्किप किए जा सकने वाले विज्ञापनों के लिए सहायता जोड़ें (ज़रूरी नहीं)

स्किप किए जा सकने वाले विज्ञापनों की सुविधा के लिए, आपको एक seek तरीका जोड़ना होगा IMA डीएआई SDK टूल का प्लेयर ऑब्जेक्ट जो प्रोग्रामैटिक रूप से वीडियो को तय जगह पर ढूंढता है, फ़्लोटिंग-पॉइंट सेकंड.

स्किप किए जा सकने वाले विज्ञापनों के लिए, आपको यह भी पक्का करना होगा कि आपने adUiNode शामिल होते हैं.

Sdk.xml

  m.player.loadUrl = Function(urlData)
    m.top.video.enableTrickPlay = false
    m.top.urlData = urlData
  End Function

  m.player.seek = Function(timeSeconds as Float)
     print "---- SDK requested seek to ----" ; timeSeconds
     m.top.video.seekMode = "accurate"
     m.top.video.seek = timeSeconds
  End Function

  m.player.adBreakStarted = Function(adBreakInfo as Object)
    print "---- Ad Break Started ---- "
    m.top.adPlaying = True
    m.top.video.enableTrickPlay = false
  End Function